[arch-commits] Commit in (4 files)

[Laurent Carlier]

    Date: Saturday, June 24, 2017 @ 06:59:02
  Author: lcarlier
Revision: 240739

moved from aur, needed for lib32-gstreamer and lib32-mesa

Added:
  lib32-libunwind/
  lib32-libunwind/repos/
  lib32-libunwind/trunk/
  lib32-libunwind/trunk/PKGBUILD

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Added: lib32-libunwind/trunk/PKGBUILD
===================================================================
--- lib32-libunwind/trunk/PKGBUILD	                        (rev 0)
+++ lib32-libunwind/trunk/PKGBUILD	2017-06-24 06:59:02 UTC (rev 240739)
@@ -0,0 +1,50 @@
+# $Id$
+# Maintainer: Laurent Carlier <lordheavym at gmail.com>
+# Contributor: Lone_Wolf <lonewolf at xs4all dot nl>
+# Contributor: Moritz Lipp <mlq at pwmt.org>
+
+_pkgbasename=libunwind
+pkgname=lib32-libunwind
+pkgver=1.2.1
+pkgrel=1
+pkgdesc="Portable and efficient C programming interface (API) to determine the call-chain of a program (32-bit)"
+arch=('x86_64')
+url="http://www.nongnu.org/libunwind/"
+license=('GPL')
+depends=('libunwind' 'lib32-xz' 'gcc-multilib')
+source=(http://download.savannah.gnu.org/releases/$_pkgbasename/$_pkgbasename-$pkgver.tar.gz{,.sig})
+sha512sums=('af7c280d2a963779a4a2711887618bc96383011e4e5d52e4085aa7fb351e55e357468f6ff85e66a216f1c6826538f498335a917a5970575c93be74c96316319b'
+            'SKIP')
+validpgpkeys=('1675C8DA2EF907FB116EB709EC52B396E6874AF2') # Dave Watson <davejwatson at fb.com> , project admin for unwind
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  
+  cd $_pkgbasename-$pkgver
+  ./configure \
+    --build=i686-pc-linux-gnu \
+    --host=i686-pc-linux-gnu \
+    --prefix=/usr \
+    --libdir=/usr/lib32 \
+    --disable-documentation 
+  make
+
+}
+
+check() {
+  cd "$srcdir/$_pkgbasename-$pkgver"
+  # This function is ``supposed'' to fail. Upstream know, but haven't fixed it.
+  make check || :
+}
+
+package_lib32-libunwind() {
+  cd $_pkgbasename-$pkgver
+  make DESTDIR="$pkgdir" install
+  
+  # this build only provides multilib binary for x86 on x86_64 , remove all includes for other architectures
+  find $pkgdir/usr/include/*.h -not -name "*x86*" -exec rm -f {} \;
+}
+
+# vim:set ts=2 sw=2 et:
+


Property changes on: lib32-libunwind/trunk/PKGBUILD
___________________________________________________________________
Added: svn:keywords
## -0,0 +1 ##
+Id
\ No newline at end of property