[arch-commits] Commit in (5 files)
Konstantin Gizdov
kgizdov at archlinux.org
Wed Feb 13 13:57:58 UTC 2019
Date: Wednesday, February 13, 2019 @ 13:57:57
Author: kgizdov
Revision: 432063
initial release
Added:
lhapdf/
lhapdf/repos/
lhapdf/trunk/
lhapdf/trunk/PKGBUILD
lhapdf/trunk/lhapdf.install
----------------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
lhapdf.install | 11 +++++++++++
2 files changed, 65 insertions(+)
Added: lhapdf/trunk/PKGBUILD
===================================================================
--- lhapdf/trunk/PKGBUILD (rev 0)
+++ lhapdf/trunk/PKGBUILD 2019-02-13 13:57:57 UTC (rev 432063)
@@ -0,0 +1,54 @@
+# Maintainer: Konstantin Gizdov <arch at kge dot pw>
+# Contributor: Frank Siegert <frank dot siegert at googlemail dot com>
+# Contributor: JP-Ellis <josh at jpellis dot me>
+pkgname=lhapdf
+pkgver=6.2.1
+pkgrel=4
+pkgdesc="A particle physics tool for evaluating PDFs from discretised data files."
+arch=('x86_64')
+url="http://lhapdf.hepforge.org/"
+license=('GPL3')
+makedepends=('cython')
+depends=('python' 'python2')
+# install=lhapdf.install
+source=("http://www.hepforge.org/archive/lhapdf/LHAPDF-${pkgver}.tar.gz")
+sha256sums=('6d57ced88592bfd0feca4b0b50839110780c3a1cd158091c075a155c5917202e')
+
+prepare() {
+ cd "${srcdir}/LHAPDF-${pkgver}"
+ sed -e 's/print Cython.Compiler.Version.version/print (Cython.Compiler.Version.version)/g' -i m4/cython.m4
+
+ cd "${srcdir}"
+ cp -r "LHAPDF-${pkgver}" "LHAPDF-${pkgver}-py2"
+}
+
+build() {
+ cd "${srcdir}/LHAPDF-${pkgver}"
+ autoreconf -i
+ ## need to rebuild Python extension code with up-to-date Cython for Python 3.7
+ ## will eventually be fixed upstream
+ touch wrappers/python/lhapdf.pyx
+ ./configure --prefix=/usr --datadir=/usr/share/lhapdf --docdir=/usr/share/doc/lhapdf --pdfdir=/usr/share/lhapdf/LHAPDF
+ make
+
+ cd "${srcdir}/LHAPDF-${pkgver}-py2"
+ autoreconf -i
+ PYTHON=/usr/bin/python2 ./configure --prefix=/usr --datadir=/usr/share/lhapdf --docdir=/usr/share/doc/lhapdf --pdfdir=/usr/share/lhapdf/LHAPDF
+ make
+}
+
+check() {
+ cd "${srcdir}/LHAPDF-${pkgver}"
+ make -k check
+
+ cd "${srcdir}/LHAPDF-${pkgver}-py2"
+ make -k check
+}
+
+package() {
+ cd "${srcdir}/LHAPDF-${pkgver}"
+ make DESTDIR="${pkgdir}/" install
+
+ cd "${srcdir}/LHAPDF-${pkgver}-py2"
+ make DESTDIR="${pkgdir}/" install
+}
Added: lhapdf/trunk/lhapdf.install
===================================================================
--- lhapdf/trunk/lhapdf.install (rev 0)
+++ lhapdf/trunk/lhapdf.install 2019-02-13 13:57:57 UTC (rev 432063)
@@ -0,0 +1,11 @@
+post_install() {
+ echo 'PDF sets are stored in /usr/share/lhapdf/LHAPDF'
+ echo 'You can download PDF sets with the "lhapdf" command like so:'
+ echo ' $ lhapdf ls'
+ echo ' # sudo lhapdf install CT10'
+}
+
+post_upgrade() {
+ echo 'To update your PDF sets, please run:'
+ echo ' # lhapdf install $(lhapdf list --outdated)'
+}
More information about the arch-commits
mailing list