[arch-commits] Commit in (5 files)

[Alexander Rødseth]

    Date: Thursday, February 14, 2019 @ 18:46:08
  Author: arodseth
Revision: 432244

New package

livewallpaper-bzr has 14 votes on AUR

Added:
  livewallpaper/
  livewallpaper/repos/
  livewallpaper/repos/community-x86_64/
  livewallpaper/trunk/
  livewallpaper/trunk/PKGBUILD

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Added: livewallpaper/trunk/PKGBUILD
===================================================================
--- livewallpaper/trunk/PKGBUILD	                        (rev 0)
+++ livewallpaper/trunk/PKGBUILD	2019-02-14 18:46:08 UTC (rev 432244)
@@ -0,0 +1,39 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contributor: Salamandar <felix at piedallu.me>
+
+pkgname=livewallpaper
+pkgver=0.5.0.333
+pkgrel=1
+pkgdesc='Animated 3D wallpapers'
+url='https://launchpad.net/livewallpaper'
+license=(GPL3)
+arch=(x86_64)
+makedepends=(bzr cmake intltool ninja vala xcftools)
+depends=(glew gobject-introspection libappindicator-gtk3 libpeas python-cairo python-opengl upower)
+source=("$pkgname::bzr+$url/trunk#revision=${pkgver##*.}")
+sha256sums=('SKIP')
+
+prepare() {
+  sed -i '/debian/d' $pkgname/CMakeLists.txt
+  sed -i "s/--quiet/--quiet --cflags-begin $CFLAGS --cflags-end/g" \
+    $pkgname/$pkgname-core/CMakeLists.txt
+}
+
+build() {
+  mkdir -p build
+  cd build
+  cmake "$srcdir/$pkgname" \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_C_FLAGS="$CFLAGS -O2 -fPIC -w" \
+    -DENABLE_OPTIMIZATION=on \
+    -DOpenGL_GL_PREFERENCE=GLVND \
+    -G Ninja
+  ninja
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -C build install
+}
+
+# getver: launchpad.net/livewallpaper/+download
+# vim: ts=2 sw=2 et: