[arch-commits] Commit in (4 files)
Bruno Pagani
archange at archlinux.org
Fri Jul 26 08:39:35 UTC 2019
Date: Friday, July 26, 2019 @ 08:39:34
Author: archange
Revision: 492818
Initial addition of python{2,}-param to [community]
Added:
python-param/
python-param/repos/
python-param/trunk/
python-param/trunk/PKGBUILD
----------+
PKGBUILD | 40 ++++++++++++++++++++++++++++++++++++++++
1 file changed, 40 insertions(+)
Added: python-param/trunk/PKGBUILD
===================================================================
--- python-param/trunk/PKGBUILD (rev 0)
+++ python-param/trunk/PKGBUILD 2019-07-26 08:39:34 UTC (rev 492818)
@@ -0,0 +1,40 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=param
+pkgbase=python-${_pkg,,}
+pkgname=("python-${_pkg,,}" "python2-${_pkg,,}")
+pkgver=1.9.1
+pkgrel=1
+pkgdesc="Make your Python code clearer and more reliable by declaring Parameters"
+arch=(any)
+url="https://param.pyviz.org/"
+license=(BSD)
+makedepends=(python-setuptools python2-setuptools)
+source=("https://files.pythonhosted.org/packages/source/p/${_pkg}/${_pkg}-${pkgver}.tar.gz")
+sha256sums=('b1bd740d436d7734b320db4752f9f747b8a6c0aaf172d7c6146de0f675dc76b5')
+
+prepare() {
+ cp -a ${_pkg}-${pkgver}{,-py2}
+}
+
+build() {
+ cd ${_pkg}-${pkgver}
+ python setup.py build
+
+ cd ../${_pkg}-${pkgver}-py2
+ python2 setup.py build
+}
+
+package_python-param() {
+ cd ${_pkg}-${pkgver}
+ python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+
+ install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
+
+package_python2-param() {
+ cd ${_pkg}-${pkgver}-py2
+ python2 setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+
+ install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
More information about the arch-commits
mailing list