[arch-commits] Commit in (4 files)

Bruno Pagani archange at archlinux.org
Fri Jul 26 10:15:59 UTC 2019


    Date: Friday, July 26, 2019 @ 10:15:58
  Author: archange
Revision: 492850

Initial addition of python{2,}-pyct to [community]

Added:
  python-pyct/
  python-pyct/repos/
  python-pyct/trunk/
  python-pyct/trunk/PKGBUILD

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Added: python-pyct/trunk/PKGBUILD
===================================================================
--- python-pyct/trunk/PKGBUILD	                        (rev 0)
+++ python-pyct/trunk/PKGBUILD	2019-07-26 10:15:58 UTC (rev 492850)
@@ -0,0 +1,42 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=pyct
+pkgbase=python-${_pkg,,}
+pkgname=("python-${_pkg,,}" "python2-${_pkg,,}")
+pkgver=0.4.6
+pkgrel=1
+pkgdesc="Python packaging Common Tasks"
+arch=(any)
+url="https://pyct.pyviz.org/"
+license=(BSD)
+makedepends=(python-setuptools python-param python2-setuptools python2-param)
+source=("https://files.pythonhosted.org/packages/source/p/${_pkg}/${_pkg}-${pkgver}.tar.gz")
+sha256sums=('df7b2d29f874cabdbc22e4f8cba2ceb895c48aa33da4e0fe679e89873e0a4c6e')
+
+prepare() {
+    cp -a ${_pkg}-${pkgver}{,-py2}
+}
+
+build() {
+    cd ${_pkg}-${pkgver}
+    python setup.py build
+
+    cd ../${_pkg}-${pkgver}-py2
+    python2 setup.py build
+}
+
+package_python-pyct() {
+    depends=(python-param)
+    cd ${_pkg}-${pkgver}
+    python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+
+    install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
+
+package_python2-pyct() {
+    depends=(python2-param)
+    cd ${_pkg}-${pkgver}-py2
+    python2 setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+
+    install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}



More information about the arch-commits mailing list