[arch-commits] Commit in reactphysics3d/repos/community-x86_64 (4 files)

[Alexander Rødseth]

    Date: Monday, November 16, 2020 @ 12:04:29
  Author: arodseth
Revision: 755208

archrelease: copy trunk to community-x86_64

Added:
  reactphysics3d/repos/community-x86_64/PKGBUILD
    (from rev 755207, reactphysics3d/trunk/PKGBUILD)
  reactphysics3d/repos/community-x86_64/reactphysics3d.pc
    (from rev 755207, reactphysics3d/trunk/reactphysics3d.pc)
Deleted:
  reactphysics3d/repos/community-x86_64/PKGBUILD
  reactphysics3d/repos/community-x86_64/reactphysics3d.pc

-------------------+
 PKGBUILD          |  117 ++++++++++++++++++++++++----------------------------
 reactphysics3d.pc |   18 ++++----
 2 files changed, 64 insertions(+), 71 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-11-16 12:04:24 UTC (rev 755207)
+++ PKGBUILD	2020-11-16 12:04:29 UTC (rev 755208)
@@ -1,62 +0,0 @@
-# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
-
-pkgbase=reactphysics3d
-pkgname=(reactphysics3d reactphysics3d-docs)
-pkgver=0.7.1
-pkgrel=3
-pkgdesc='Physics engine'
-arch=(x86_64)
-url='https://www.reactphysics3d.com'
-license=(ZLIB)
-makedepends=(cmake ninja)
-source=("https://github.com/DanielChappuis/reactphysics3d/releases/download/v$pkgver/reactphysics3d-$pkgver.tar.gz"
-        "https://www.reactphysics3d.com/documentation/manual/ReactPhysics3D-UserManual.pdf"
-        "cmake.patch::https://github.com/DanielChappuis/reactphysics3d/commit/94076513166704edafd0567b438fa52c05569e25.patch"
-        "$pkgbase.pc")
-sha256sums=('9e55cc79882120297974b331b81c55fa8e4a6802057e55c3922ed301dd83a20a'
-            '7c6307724bfef92f351150d522fb1a9050400f404e0a3be231946d2b633cb1bd'
-            'c3046803795f4072a6067a24bfb1af9927bc1c71866a570390e71f04bedcf376'
-            '673dbd5bbee66d8a0f357fbc46cd56eb070088bbf30a5efeee7e5162ef4450a1')
-
-prepare() {
-  # Prepare to build a shared library
-  sed -i 's|ADD_LIBRARY(reactphysics3d|ADD_LIBRARY(reactphysics3d SHARED|g' \
-    "$pkgbase-$pkgver/CMakeLists.txt"
-  # Apply patch
-  cd "$pkgbase-$pkgver"
-  patch -p1 -i ../cmake.patch
-}
-
-build() {
-  mkdir -p build
-  cd build
-  cmake "$srcdir/$pkgbase-$pkgver" \
-    -D CMAKE_CXX_FLAGS="$CXXFLAGS -w" \
-    -D CMAKE_BUILD_TYPE=Release \
-    -D CMAKE_INSTALL_PREFIX=/usr \
-    -D CMAKE_INSTALL_LIBDIR=lib \
-    -D RP3D_DOUBLE_PRECISION_ENABLED=ON \
-    -D RP3D_COMPILE_TESTS=ON \
-    -G Ninja
-  ninja
-}
-
-package_reactphysics3d() {
-  depends=(gcc-libs)
-  DESTDIR="$pkgdir" ninja -C build install
-  install -Dm 644 "$pkgbase.pc" \
-    "$pkgdir/usr/lib/pkgconfig/$pkgbase.pc"
-  install -Dm 644 "$pkgbase-$pkgver/LICENSE" \
-    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
-}
-
-package_reactphysics3d-docs() {
-  pkgdesc='Physics engine (user manual)'
-  install -Dm 644 "ReactPhysics3D-UserManual.pdf" \
-    "$pkgdir/usr/share/doc/$pkgname/UserManual.pdf"
-  install -Dm 644 "$pkgbase-$pkgver/LICENSE" \
-    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
-}
-
-# getver: github.com/DanielChappuis/reactphysics3d/releases
-# vim: ts=2 sw=2 et:

Copied: reactphysics3d/repos/community-x86_64/PKGBUILD (from rev 755207, reactphysics3d/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-11-16 12:04:29 UTC (rev 755208)
@@ -0,0 +1,55 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+
+pkgbase=reactphysics3d
+pkgname=(reactphysics3d reactphysics3d-docs)
+pkgver=0.8.0
+pkgrel=1
+pkgdesc='Physics engine'
+arch=(x86_64)
+url='https://www.reactphysics3d.com'
+license=(ZLIB)
+makedepends=(cmake ninja)
+source=("https://github.com/DanielChappuis/reactphysics3d/releases/download/v$pkgver/reactphysics3d-$pkgver.tar.gz"
+        "https://www.reactphysics3d.com/documentation/manual/ReactPhysics3D-UserManual.pdf"
+        "$pkgbase.pc")
+sha256sums=('a58c6e88311e2d7da6ae60f486097e1fe522682cd84b0f93e0f97d39377571cb'
+            '5f866e28f7a64a0eddb0885536b6a1da524dd4b45c7a871e802eaeb659617882'
+            '38c8e276bc0601434f27e161036f310d40a28bef527dddabf5140375bf5bb712')
+
+prepare() {
+  find "$srcdir/$pkgbase" -name .DS_Store -delete
+}
+
+build() {
+  mkdir -p build
+  cd build
+  cmake "$srcdir/$pkgbase" \
+    -D BUILD_SHARED_LIBS=ON \
+    -D CMAKE_CXX_FLAGS="$CXXFLAGS -w" \
+    -D CMAKE_BUILD_TYPE=Release \
+    -D CMAKE_INSTALL_PREFIX=/usr \
+    -D CMAKE_INSTALL_LIBDIR=lib \
+    -D RP3D_DOUBLE_PRECISION_ENABLED=ON \
+    -D RP3D_COMPILE_TESTS=OFF \
+    -G Ninja
+  ninja
+}
+
+package_reactphysics3d() {
+  depends=(gcc-libs)
+  DESTDIR="$pkgdir" ninja -C build install
+  install -Dm 644 "$pkgbase.pc" \
+    "$pkgdir/usr/lib/pkgconfig/$pkgbase.pc"
+  install -Dm 644 "$pkgbase/LICENSE" \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+package_reactphysics3d-docs() {
+  pkgdesc='Physics engine (user manual)'
+  install -Dm 644 "ReactPhysics3D-UserManual.pdf" \
+    "$pkgdir/usr/share/doc/$pkgname/UserManual.pdf"
+  install -Dm 644 "$pkgbase/LICENSE" \
+    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}
+
+# getver: github.com/DanielChappuis/reactphysics3d/releases

Deleted: reactphysics3d.pc
===================================================================
--- reactphysics3d.pc	2020-11-16 12:04:24 UTC (rev 755207)
+++ reactphysics3d.pc	2020-11-16 12:04:29 UTC (rev 755208)
@@ -1,9 +0,0 @@
-prefix=/usr
-libdir=${prefix}/lib
-includedir=${prefix}/include/reactphysics3d
-
-Name: reactphysics3d
-Description: ReactPhysics3D headers
-Version: 0.7.1
-Cflags: -I${includedir}
-Libs: -L${libdir} -lreactphysics3d

Copied: reactphysics3d/repos/community-x86_64/reactphysics3d.pc (from rev 755207, reactphysics3d/trunk/reactphysics3d.pc)
===================================================================
--- reactphysics3d.pc	                        (rev 0)
+++ reactphysics3d.pc	2020-11-16 12:04:29 UTC (rev 755208)
@@ -0,0 +1,9 @@
+prefix=/usr
+libdir=${prefix}/lib
+includedir=${prefix}/include/reactphysics3d
+
+Name: reactphysics3d
+Description: ReactPhysics3D headers
+Version: 0.8.0
+Cflags: -I${includedir}
+Libs: -L${libdir} -lreactphysics3d