[arch-commits] Commit in gedit/repos (2 files)

[Jan Steffens]

    Date: Saturday, September 26, 2020 @ 23:12:36
  Author: heftig
Revision: 396680

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gedit/repos/gnome-unstable-x86_64/
  gedit/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 396679, gedit/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: gedit/repos/gnome-unstable-x86_64/PKGBUILD (from rev 396679, gedit/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-09-26 23:12:36 UTC (rev 396680)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gedit
+pkgver=3.38.0
+pkgrel=1
+pkgdesc="GNOME Text Editor"
+url="https://wiki.gnome.org/Apps/Gedit"
+arch=(x86_64)
+license=(GPL)
+depends=(gtksourceview4 gsettings-desktop-schemas libpeas gspell python-gobject
+         dconf tepl)
+makedepends=(yelp-tools vala gobject-introspection git gtk-doc meson
+             appstream-glib desktop-file-utils libxml2)
+optdepends=('gedit-plugins: Additional features')
+conflicts=('gedit-code-assistance<=3.16.0+4+gd19b879-1')
+groups=(gnome)
+_commit=21fac3f0c87db0db104d7af7eaeb6f63d8216a14  # tags/3.38.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gedit.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  git submodule init
+  git submodule set-url subprojects/libgd "$srcdir/libgd"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D gtk_doc=true \
+    -D require_all_tests=true
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}