[arch-commits] Commit in gnome-shell/repos (3 files)

[Jan Steffens]

    Date: Saturday, September 26, 2020 @ 23:15:43
  Author: heftig
Revision: 396683

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-shell/repos/gnome-unstable-x86_64/
  gnome-shell/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 396682, gnome-shell/trunk/PKGBUILD)
  gnome-shell/repos/gnome-unstable-x86_64/gnome-shell.install
    (from rev 396682, gnome-shell/trunk/gnome-shell.install)

---------------------+
 PKGBUILD            |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 gnome-shell.install |    7 +++++++
 2 files changed, 56 insertions(+)

Copied: gnome-shell/repos/gnome-unstable-x86_64/PKGBUILD (from rev 396682, gnome-shell/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-09-26 23:15:43 UTC (rev 396683)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Flamelab <panosfilip at gmail.com
+
+pkgname=gnome-shell
+pkgver=3.38.0+17+g84cff8920
+pkgrel=1
+epoch=1
+pkgdesc="Next generation desktop shell"
+url="https://wiki.gnome.org/Projects/GnomeShell"
+arch=(x86_64)
+license=(GPL2)
+depends=(accountsservice gcr gjs gnome-bluetooth upower gnome-session gnome-settings-daemon
+         gnome-themes-extra gsettings-desktop-schemas libcanberra-pulse libgdm libsecret
+         mutter nm-connection-editor unzip gstreamer libibus gnome-autoar gnome-disk-utility)
+makedepends=(gtk-doc gnome-control-center evolution-data-server gobject-introspection git meson
+             sassc asciidoc bash-completion)
+optdepends=('gnome-control-center: System settings'
+            'evolution-data-server: Evolution calendar integration')
+groups=(gnome)
+install=gnome-shell.install
+_commit=84cff8920509f99be47c017bd8bdf8e45ea90535  # master
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+  
+build() {
+  arch-meson $pkgname build -D gtk_doc=true
+  meson compile -C build
+}
+
+package() {
+  depends+=(libmutter-7.so)
+  DESTDIR="$pkgdir" meson install -C build
+}

Copied: gnome-shell/repos/gnome-unstable-x86_64/gnome-shell.install (from rev 396682, gnome-shell/trunk/gnome-shell.install)
===================================================================
--- gnome-unstable-x86_64/gnome-shell.install	                        (rev 0)
+++ gnome-unstable-x86_64/gnome-shell.install	2020-09-26 23:15:43 UTC (rev 396683)
@@ -0,0 +1,7 @@
+post_install() {
+  setcap cap_sys_nice+ep usr/bin/gnome-shell
+}
+
+post_upgrade() {
+  post_install
+}