[arch-commits] Commit in epiphany/repos (2 files)

[Jan Steffens]

    Date: Saturday, September 26, 2020 @ 23:34:21
  Author: heftig
Revision: 396687

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  epiphany/repos/gnome-unstable-x86_64/
  epiphany/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 396686, epiphany/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: epiphany/repos/gnome-unstable-x86_64/PKGBUILD (from rev 396686, epiphany/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-09-26 23:34:21 UTC (rev 396687)
@@ -0,0 +1,42 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=epiphany
+pkgver=3.38.0
+pkgrel=1
+pkgdesc="A GNOME web browser based on the WebKit rendering engine"
+url="https://wiki.gnome.org/Apps/Web"
+arch=(x86_64)
+license=(GPL)
+depends=(webkit2gtk gcr icu libdazzle libhandy libportal)
+makedepends=(docbook-xml startup-notification lsb-release gobject-introspection yelp-tools
+             appstream-glib git meson)
+checkdepends=(xorg-server-xvfb aspell hspell hunspell nuspell libvoikko)
+groups=(gnome)
+_commit=38c6671c5b8f46b061f1f4be1fa25b097d09beeb  # tags/3.38.0^0
+source=("git+https://gitlab.gnome.org/GNOME/epiphany.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local' \
+    meson test -C build --print-errorlogs
+}
+
+package() {
+  DESTDIR="$pkgdir" meson install -C build
+}