[arch-commits] Commit in gnome-terminal/repos (2 files)

[Jan Steffens]

    Date: Saturday, September 26, 2020 @ 23:34:21
  Author: heftig
Revision: 396688

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-terminal/repos/gnome-unstable-x86_64/
  gnome-terminal/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 396686, gnome-terminal/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: gnome-terminal/repos/gnome-unstable-x86_64/PKGBUILD (from rev 396686, gnome-terminal/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2020-09-26 23:34:21 UTC (rev 396688)
@@ -0,0 +1,45 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-terminal
+pkgver=3.38.0
+pkgrel=1
+pkgdesc="The GNOME Terminal Emulator"
+url="https://wiki.gnome.org/Apps/Terminal"
+arch=(x86_64)
+license=(GPL)
+depends=('vte3>=0.60.0' gsettings-desktop-schemas)
+makedepends=(itstool docbook-xsl libnautilus-extension appstream-glib
+             gnome-shell vala yelp-tools git)
+groups=(gnome)
+_commit=2f365483950a99c14d9cf88a21a4820b16780fc4  # tags/3.38.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-terminal.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --libexecdir=/usr/lib --disable-static --with-nautilus-extension
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}