[arch-commits] Commit in rizin/repos (2 files)

[Levente Polyak]

    Date: Monday, April 12, 2021 @ 20:14:40
  Author: anthraxx
Revision: 916023

archrelease: copy trunk to community-staging-x86_64

Added:
  rizin/repos/community-staging-x86_64/
  rizin/repos/community-staging-x86_64/PKGBUILD
    (from rev 916022, rizin/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: rizin/repos/community-staging-x86_64/PKGBUILD (from rev 916022, rizin/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-04-12 20:14:40 UTC (rev 916023)
@@ -0,0 +1,46 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=rizin
+pkgver=0.2.0
+pkgrel=1
+pkgdesc='Open-source tools to disasm, debug, analyze and manipulate binary files'
+url='https://rizin.re'
+arch=('x86_64')
+license=('GPL3' 'LGPL3')
+depends=(
+  'sh' 'capstone' 'libcapstone.so' 'openssl' 'libzip' 'zlib' 'lz4' 'xxhash'
+  'libxxhash.so' 'file' 'libuv' 'tree-sitter' 'libtree-sitter.so'
+  'libzip.so' 'libmagic.so')
+makedepends=('meson' 'ninja' 'python')
+optdepends=('rz-ghidra: ghidra decompiler plugin')
+options=('!emptydirs')
+source=(https://github.com/rizinorg/rizin/releases/download/v${pkgver}/rizin-src-v${pkgver}.tar.xz)
+sha512sums=('d9522423110553e4b0ac80bfce6edd4b642a1df74e76b77ab23a7b13a37a37a3858ad294e14742a349265ed509345fb0277b910de6814eee3b970a6b9b344d12')
+b2sums=('2db80b74cb1f40387e8d173fea19418d0a95be6a93acd5fb39da2fd51a0db6d77b20a7e8c551c461ce10ec2a39aa51958c238cd8dad7a357cd886804e87efa93')
+
+build() {
+  cd ${pkgname}-v${pkgver}
+  arch-meson build \
+    -D use_sys_capstone=enabled \
+    -D use_capstone_version=v4 \
+    -D use_sys_magic=enabled \
+    -D use_sys_libzip=enabled \
+    -D use_sys_zlib=enabled \
+    -D use_sys_lz4=enabled \
+    -D use_sys_xxhash=enabled \
+    -D use_sys_openssl=enabled \
+    -D use_sys_tree_sitter=enabled \
+    -D use_libuv=true \
+    -D use_webui=true \
+    -D local=disabled
+  ninja -C build
+}
+
+package() {
+  cd ${pkgname}-v${pkgver}
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -d "${pkgdir}/usr/share/doc/rizin"
+  cp -r doc/* "${pkgdir}/usr/share/doc/rizin"
+}
+
+# vim: ts=2 sw=2 et: