[arch-commits] Commit in rizin/repos (2 files)

[Levente Polyak]

    Date: Monday, April 26, 2021 @ 23:07:27
  Author: anthraxx
Revision: 924635

archrelease: copy trunk to community-staging-x86_64

Added:
  rizin/repos/community-staging-x86_64/
  rizin/repos/community-staging-x86_64/PKGBUILD
    (from rev 924634, rizin/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: rizin/repos/community-staging-x86_64/PKGBUILD (from rev 924634, rizin/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-04-26 23:07:27 UTC (rev 924635)
@@ -0,0 +1,46 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=rizin
+pkgver=0.2.1
+pkgrel=1
+pkgdesc='Open-source tools to disasm, debug, analyze and manipulate binary files'
+url='https://rizin.re'
+arch=('x86_64')
+license=('GPL3' 'LGPL3')
+depends=(
+  'sh' 'capstone' 'libcapstone.so' 'openssl' 'libzip' 'zlib' 'lz4' 'xxhash'
+  'libxxhash.so' 'file' 'libuv' 'tree-sitter' 'libtree-sitter.so'
+  'libzip.so' 'libmagic.so')
+makedepends=('meson' 'ninja' 'python')
+optdepends=('rz-ghidra: ghidra decompiler plugin')
+options=('!emptydirs')
+source=(https://github.com/rizinorg/rizin/releases/download/v${pkgver}/rizin-src-v${pkgver}.tar.xz)
+sha512sums=('4d0a68971a8fe1de3860f8ee18197606f59c22d4c24f3fcce691c73b45c8fe8c356a9b411604e9c3d4e5bb01f695b6ead32cdc217134eb4ddfec76867c16c327')
+b2sums=('3ce048c5e93afa43b33bb7c36e7f7a96734886a44a67339c18b36de84b6e3dd015aa49fd048815bc7cb26a39bd3c44ebd00227fdb0c3dc9d9f07ff2ff1f1948d')
+
+build() {
+  cd ${pkgname}-v${pkgver}
+  arch-meson build \
+    -D use_sys_capstone=enabled \
+    -D use_capstone_version=v4 \
+    -D use_sys_magic=enabled \
+    -D use_sys_libzip=enabled \
+    -D use_sys_zlib=enabled \
+    -D use_sys_lz4=enabled \
+    -D use_sys_xxhash=enabled \
+    -D use_sys_openssl=enabled \
+    -D use_sys_tree_sitter=enabled \
+    -D use_libuv=true \
+    -D use_webui=true \
+    -D local=disabled
+  ninja -C build
+}
+
+package() {
+  cd ${pkgname}-v${pkgver}
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -d "${pkgdir}/usr/share/doc/rizin"
+  cp -r doc/* "${pkgdir}/usr/share/doc/rizin"
+}
+
+# vim: ts=2 sw=2 et: