[arch-commits] Commit in tailscale/repos (3 files)

[Morten Linderud]

    Date: Sunday, January 3, 2021 @ 21:45:14
  Author: foxboron
Revision: 805953

archrelease: copy trunk to community-x86_64

Added:
  tailscale/repos/community-x86_64/
  tailscale/repos/community-x86_64/PKGBUILD
    (from rev 805952, tailscale/trunk/PKGBUILD)
  tailscale/repos/community-x86_64/tailscale.install
    (from rev 805952, tailscale/trunk/tailscale.install)

-------------------+
 PKGBUILD          |   59 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 tailscale.install |   12 ++++++++++
 2 files changed, 71 insertions(+)

Copied: tailscale/repos/community-x86_64/PKGBUILD (from rev 805952, tailscale/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2021-01-03 21:45:14 UTC (rev 805953)
@@ -0,0 +1,59 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Contributor: David Anderson <dave at natulte.net>
+
+pkgname=tailscale
+pkgver=1.2.10
+pkgrel=2
+pkgdesc="A mesh VPN that makes it easy to connect your devices, wherever they are."
+arch=("x86_64")
+url="https://tailscale.com"
+license=("MIT")
+makedepends=("git" "go")
+depends=("glibc")
+backup=("etc/default/tailscaled")
+_commit=e480f8ddf6f7334fda1b3d0dd1b500f2f01f961b	#refs/tags/v1.2.10^{}
+source=("git+https://github.com/tailscale/tailscale.git#commit=${_commit}")
+sha256sums=('SKIP')
+install="tailscale.install"
+
+pkgver() {
+  cd "${pkgname}"
+  git describe --tags | sed 's/^[vV]//;s/-/+/g'
+}
+
+prepare() {
+    cd "${pkgname}"
+    go mod vendor
+}
+
+build() {
+    cd "${pkgname}"
+    eval "$(./version/version.sh)"
+    export CGO_CPPFLAGS="${CPPFLAGS}"
+    export CGO_CFLAGS="${CFLAGS}"
+    export CGO_CXXFLAGS="${CXXFLAGS}"
+    export CGO_LDFLAGS="${LDFLAGS}"
+    export GOFLAGS="-buildmode=pie -trimpath -mod=readonly -modcacherw"
+    GO_LDFLAGS="\
+        -linkmode=external \
+        -X tailscale.com/version.Long=${VERSION_LONG} \
+        -X tailscale.com/version.Short=${VERSION_SHORT} \
+        -X tailscale.com/version.GitCommit=${VERSION_GIT_HASH}"
+    for cmd in ./cmd/tailscale ./cmd/tailscaled; do
+        go build -v -tags xversion -ldflags "$GO_LDFLAGS" "$cmd"
+    done
+}
+
+#TODO: Figure out why tests are failing
+# check() {
+#     cd "${pkgname}"
+#     go test $(go list ./... | grep -v tsdns_test)
+# }
+
+package() {
+    cd "${pkgname}"
+    install -Dm755 tailscale tailscaled -t "$pkgdir/usr/bin"
+    install -Dm644 cmd/tailscaled/tailscaled.defaults "$pkgdir/etc/default/tailscaled"
+    install -Dm644 cmd/tailscaled/tailscaled.service -t "$pkgdir/usr/lib/systemd/system"
+    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}

Copied: tailscale/repos/community-x86_64/tailscale.install (from rev 805952, tailscale/trunk/tailscale.install)
===================================================================
--- community-x86_64/tailscale.install	                        (rev 0)
+++ community-x86_64/tailscale.install	2021-01-03 21:45:14 UTC (rev 805953)
@@ -0,0 +1,12 @@
+# -*- mode: shell-script -*-
+
+post_install() {
+    echo -e "\n\e[1m Tailscale $1\e[0m\n"
+    cat <<EOF
+To start using Tailscale:
+
+    sudo systemctl enable --now tailscaled.service
+    sudo tailscale up
+
+EOF
+}