[arch-commits] Commit in yder (3 files)

[Maxime Gauduin]

    Date: Thursday, January 7, 2021 @ 10:15:58
  Author: alucryd
Revision: 811541

archrelease: copy trunk to community-staging-x86_64

Added:
  yder/repos/
  yder/repos/community-staging-x86_64/
  yder/repos/community-staging-x86_64/PKGBUILD
    (from rev 811540, yder/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: yder/repos/community-staging-x86_64/PKGBUILD (from rev 811540, yder/trunk/PKGBUILD)
===================================================================
--- repos/community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-staging-x86_64/PKGBUILD	2021-01-07 10:15:58 UTC (rev 811541)
@@ -0,0 +1,47 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=yder
+pkgver=1.4.12
+pkgrel=1
+pkgdesc='Logging library for C applications'
+arch=(x86_64)
+url=https://github.com/babelouest/yder
+license=(LGPL2.1)
+depends=(
+  glibc
+  liborcania.so
+  libsystemd.so
+)
+makedepends=(
+  cmake
+  doxygen
+  git
+  graphviz
+  ninja
+)
+provides=(libyder.so)
+_tag=c7559831fb3834a7133596a355b001f79569ad21
+source=(git+https://github.com/babelouest/yder.git#tag=${_tag})
+validpgpkeys=(8405B02FCC28EF9744C8F253FE82139440BD22B9) # Nicolas Mora <nicolas at babelouest.org>
+b2sums=(SKIP)
+
+pkgver() {
+  cd yder
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cmake -S yder -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_YDER_DOCUMENTATION=ON
+  ninja -C build doc
+}
+
+package() {
+  DESTDIR="${pkgdir}" ninja -C build install
+  install -dm 755 "${pkgdir}"/usr/share/doc
+  cp -dr --no-preserve=ownership yder/doc/html "${pkgdir}"/usr/share/doc/yder/
+}
+
+# vim: ts=2 sw=2 et: