[arch-commits] Commit in ulfius (3 files)

[Maxime Gauduin]

    Date: Thursday, January 7, 2021 @ 10:18:37
  Author: alucryd
Revision: 811542

archrelease: copy trunk to community-staging-x86_64

Added:
  ulfius/repos/
  ulfius/repos/community-staging-x86_64/
  ulfius/repos/community-staging-x86_64/PKGBUILD
    (from rev 811541, ulfius/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: ulfius/repos/community-staging-x86_64/PKGBUILD (from rev 811541, ulfius/trunk/PKGBUILD)
===================================================================
--- repos/community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-staging-x86_64/PKGBUILD	2021-01-07 10:18:37 UTC (rev 811542)
@@ -0,0 +1,50 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=ulfius
+pkgver=2.7.1
+pkgrel=1
+pkgdesc='Single-Sign-On (SSO) server with multiple factor authentication'
+arch=(x86_64)
+url=https://github.com/babelouest/ulfius
+license=(LGPL2.1)
+depends=(
+  glibc
+  gnutls
+  jansson
+  libcurl.so
+  libmicrohttpd.so
+  liborcania.so
+  libyder.so
+  zlib
+)
+makedepends=(
+  cmake
+  doxygen
+  git
+  graphviz
+  ninja
+)
+_tag=34b9f1494f74a52c8576ccb3a90deb9c3f44c7c6
+source=(git+https://github.com/babelouest/ulfius.git#tag=${_tag})
+validpgpkeys=(8405B02FCC28EF9744C8F253FE82139440BD22B9) # Nicolas Mora <nicolas at babelouest.org>
+b2sums=(SKIP)
+
+pkgver() {
+  cd ulfius
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cmake -S ulfius -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_ULFIUS_DOCUMENTATION=ON
+  ninja -C build doc
+}
+
+package() {
+  DESTDIR="${pkgdir}" ninja -C build install
+  cp -dr --no-preserve=ownership ulfius/doc/html "${pkgdir}"/usr/share/doc/ulfius/
+}
+
+# vim: ts=2 sw=2 et: