[arch-commits] Commit in (4 files)

[Bruno Pagani]

    Date: Monday, June 21, 2021 @ 00:44:19
  Author: archange
Revision: 966196

Initial addition of fiona to [community]

Dependency for geopandas

Added:
  python-fiona/
  python-fiona/repos/
  python-fiona/trunk/
  python-fiona/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Added: python-fiona/trunk/PKGBUILD
===================================================================
--- python-fiona/trunk/PKGBUILD	                        (rev 0)
+++ python-fiona/trunk/PKGBUILD	2021-06-21 00:44:19 UTC (rev 966196)
@@ -0,0 +1,48 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=Fiona
+pkgname=python-${_pkg,,}
+pkgver=1.8.20
+pkgrel=1
+pkgdesc="Read and write geographic data files"
+arch=(x86_64)
+url="https://github.com/Toblerity/Fiona"
+license=(BSD)
+depends=(
+    gdal
+    python-attrs
+    python-certifi
+    python-click
+    python-click-plugins
+    python-cligj
+    python-munch
+    python-six
+)
+optdepends=(
+    'python-shapely: fio-calc functionnality'
+    'python-boto3: s3 support'
+)
+makedepends=(cython python-setuptools)
+checkdepends=(python-pytest python-boto3 python-pytz python-shapely)
+source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+sha256sums=('a70502d2857b82f749c09cb0dea3726787747933a2a1599b5ab787d74e3c143b')
+
+build() {
+  cd ${_pkg}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkg}-${pkgver}
+  mv fiona{,.bak} # Avoid non-working local import
+  local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+  # Currently they are 67 failing tests but no time to investigate
+  PYTHONPATH="${PWD}"/build/lib.linux-${CARCH}-${python_version}/ pytest -m "not wheel" || echo "Warning: failed tests"
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  mv fiona{.bak,}
+  python setup.py install --prefix=/usr --root="${pkgdir}" --skip-build --optimize=1
+  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}