[arch-commits] Commit in (4 files)

[Brett Cornwall]

    Date: Monday, June 21, 2021 @ 04:12:44
  Author: ainola
Revision: 966366

Add csound-plugins, featuring extra opcodes

Added:
  csound-plugins/
  csound-plugins/repo/
  csound-plugins/trunk/
  csound-plugins/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Added: csound-plugins/trunk/PKGBUILD
===================================================================
--- csound-plugins/trunk/PKGBUILD	                        (rev 0)
+++ csound-plugins/trunk/PKGBUILD	2021-06-21 04:12:44 UTC (rev 966366)
@@ -0,0 +1,48 @@
+# Maintainer: Brett Cornwall <ainola at archlinux.org>
+
+pkgname=csound-plugins
+pkgver=r32.e2c9cf5
+pkgrel=1
+pkgdesc="Extra opcodes for Csound"
+arch=(x86_64)
+url="https://github.com/csound/plugins"
+license=('GPL')
+groups=('pro-audio')
+depends=(
+	'csound'
+	'python'
+)
+makedepends=(
+	'cmake'
+	'faust'
+	'fltk'
+	'git'
+	'libpng'
+)
+optdepends=(
+	'faust: for libfaustcsound plugin'
+	'fltk: for libvirtual and libwidgets plugins'
+	'libpng: for libimage plugin'
+)
+source=('git+https://github.com/csound/plugins.git#tag=e2c9cf5deded1e57ffbfe5d12e27489ba2b9b9c3')
+sha256sums=('SKIP')
+
+pkgver() {
+	cd plugins
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+	mkdir build
+	# libchua is already built by csound for now.
+	cmake -B build -S plugins \
+		-DCMAKE_BUILD_TYPE='None' \
+		-DCMAKE_INSTALL_PREFIX='/usr' \
+		-DBUILD_CHUA_OPCODES='OFF' \
+		-Wno-dev
+	make -C build
+}
+
+package() {
+	make -C build DESTDIR="$pkgdir/" install
+}