[arch-commits] Commit in (starship starship/trunk starship/trunk/PKGBUILD)

Maxime Gauduin alucryd at archlinux.org
Thu Mar 4 09:11:04 UTC 2021


    Date: Thursday, March 4, 2021 @ 09:11:04
  Author: alucryd
Revision: 880162

add starship

Added:
  starship/
  starship/trunk/
  starship/trunk/PKGBUILD

----------+
 PKGBUILD |   65 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

Added: starship/trunk/PKGBUILD
===================================================================
--- starship/trunk/PKGBUILD	                        (rev 0)
+++ starship/trunk/PKGBUILD	2021-03-04 09:11:04 UTC (rev 880162)
@@ -0,0 +1,65 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Kevin Song <kevin.s05 at gmail.com>
+
+pkgname=starship
+pkgdesc='The cross-shell prompt for astronauts'
+pkgver=0.50.0
+pkgrel=2
+arch=(x86_64)
+url=https://starship.rs/
+license=(ISC)
+depends=(
+  gcc-libs
+  glibc
+  libgit2.so
+  openssl
+)
+optdepends=(
+  'noto-fonts-emoji: emoji support for terminals'
+  'powerline-fonts: powerline symbols for terminals'
+)
+makedepends=(
+  git
+  rust
+)
+checkdepends=(python)
+_tag=0558b38e3f211eafeca56d39e9da899bcdf8de99
+source=(git+https://github.com/starship/starship.git#tag=${_tag})
+b2sums=(SKIP)
+
+prepare() {
+  cargo fetch \
+    --locked \
+    --manifest-path starship/Cargo.toml
+}
+
+pkgver() {
+  cd starship
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cargo build \
+    --release \
+    --frozen \
+    --manifest-path starship/Cargo.toml
+}
+
+check() {
+  cargo test \
+    --release \
+    --frozen \
+    --manifest-path starship/Cargo.toml
+}
+
+package() {
+  cargo install \
+    --frozen \
+    --offline \
+    --no-track \
+    --path starship \
+    --root "${pkgdir}"/usr
+    install -Dm 644 starship/LICENSE -t "${pkgdir}"/usr/share/licenses/starship/
+}
+
+# vim: ts=2 sw=2 et:



More information about the arch-commits mailing list