[arch-commits] Commit in starship (3 files)

[Maxime Gauduin]

    Date: Thursday, March 4, 2021 @ 09:53:41
  Author: alucryd
Revision: 880163

archrelease: copy trunk to community-x86_64

Added:
  starship/repos/
  starship/repos/community-x86_64/
  starship/repos/community-x86_64/PKGBUILD
    (from rev 880162, starship/trunk/PKGBUILD)

----------+
 PKGBUILD |   65 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)

Copied: starship/repos/community-x86_64/PKGBUILD (from rev 880162, starship/trunk/PKGBUILD)
===================================================================
--- repos/community-x86_64/PKGBUILD	                        (rev 0)
+++ repos/community-x86_64/PKGBUILD	2021-03-04 09:53:41 UTC (rev 880163)
@@ -0,0 +1,65 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Kevin Song <kevin.s05 at gmail.com>
+
+pkgname=starship
+pkgdesc='The cross-shell prompt for astronauts'
+pkgver=0.50.0
+pkgrel=2
+arch=(x86_64)
+url=https://starship.rs/
+license=(ISC)
+depends=(
+  gcc-libs
+  glibc
+  libgit2.so
+  openssl
+)
+optdepends=(
+  'noto-fonts-emoji: emoji support for terminals'
+  'powerline-fonts: powerline symbols for terminals'
+)
+makedepends=(
+  git
+  rust
+)
+checkdepends=(python)
+_tag=0558b38e3f211eafeca56d39e9da899bcdf8de99
+source=(git+https://github.com/starship/starship.git#tag=${_tag})
+b2sums=(SKIP)
+
+prepare() {
+  cargo fetch \
+    --locked \
+    --manifest-path starship/Cargo.toml
+}
+
+pkgver() {
+  cd starship
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cargo build \
+    --release \
+    --frozen \
+    --manifest-path starship/Cargo.toml
+}
+
+check() {
+  cargo test \
+    --release \
+    --frozen \
+    --manifest-path starship/Cargo.toml
+}
+
+package() {
+  cargo install \
+    --frozen \
+    --offline \
+    --no-track \
+    --path starship \
+    --root "${pkgdir}"/usr
+    install -Dm 644 starship/LICENSE -t "${pkgdir}"/usr/share/licenses/starship/
+}
+
+# vim: ts=2 sw=2 et: