[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, May 30, 2021 @ 22:38:07
  Author: felixonmars
Revision: 950848

addpkg: ocaml-stdio 0.14.0-2

Added:
  ocaml-stdio/
  ocaml-stdio/repos/
  ocaml-stdio/trunk/
  ocaml-stdio/trunk/PKGBUILD

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Added: ocaml-stdio/trunk/PKGBUILD
===================================================================
--- ocaml-stdio/trunk/PKGBUILD	                        (rev 0)
+++ ocaml-stdio/trunk/PKGBUILD	2021-05-30 22:38:07 UTC (rev 950848)
@@ -0,0 +1,37 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Peukert <dan.peukert at gmail.co>
+# Contributor: Dimitris Kiziridis <ragouel at outlook dot com>
+# Contributor: Jakob Gahde <j5lx at fmail.co.uk>
+
+_projectname='stdio'
+pkgname="ocaml-$_projectname"
+pkgver=0.14.0
+pkgrel=2
+pkgdesc='Standard IO Library for OCaml'
+arch=('x86_64')
+url="https://github.com/janestreet/$_projectname"
+license=('MIT')
+depends=('glibc' 'ocaml' 'ocaml-base')
+makedepends=('dune')
+options=('!strip')
+source=("$pkgname-$pkgver-$pkgrel.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha256sums=('1685cb86b29b07075ba6028431cf4e3f687c071d89996a6437442db2dfe1b0b2')
+
+_sourcedirectory="$_projectname-$pkgver"
+
+build() {
+	cd "$srcdir/$_sourcedirectory/"
+	dune build --release --verbose
+}
+
+package() {
+	cd "$srcdir/$_sourcedirectory/"
+	DESTDIR="$pkgdir" dune install --prefix '/usr' --libdir 'lib/ocaml' --release --verbose
+
+	install -dm755 "$pkgdir/usr/share/doc/$pkgname"
+	mv "$pkgdir/usr/doc/$_projectname/"* "$pkgdir/usr/share/doc/$pkgname/"
+	rm -r "$pkgdir/usr/doc/"
+
+	install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
+	ln -sf "/usr/share/doc/$pkgname/LICENSE.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
+}