[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Sunday, May 30, 2021 @ 22:54:19
  Author: felixonmars
Revision: 950900

addpkg: ocaml-stdlib-shims 0.3.0-1

Added:
  ocaml-stdlib-shims/
  ocaml-stdlib-shims/repos/
  ocaml-stdlib-shims/trunk/
  ocaml-stdlib-shims/trunk/PKGBUILD

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Added: ocaml-stdlib-shims/trunk/PKGBUILD
===================================================================
--- ocaml-stdlib-shims/trunk/PKGBUILD	                        (rev 0)
+++ ocaml-stdlib-shims/trunk/PKGBUILD	2021-05-30 22:54:19 UTC (rev 950900)
@@ -0,0 +1,40 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Peukert <daniel at peukert.cc>
+
+_projectname='stdlib-shims'
+pkgname="ocaml-$_projectname"
+pkgver=0.3.0
+pkgrel=1
+pkgdesc='Shim to substitute `Pervasives` with `Stdlib` before 4.08'
+arch=('x86_64')
+url="https://github.com/ocaml/$_projectname"
+license=('custom:LGPL2.1 with linking exception')
+depends=('ocaml')
+makedepends=('dune')
+options=('!strip')
+source=("$pkgname-$pkgver-$pkgrel.tar.gz::$url/archive/$pkgver.tar.gz")
+sha256sums=('6d0386313a021146300011549180fcd4e94f7ac3c3bf021ff165f6558608f0c2')
+
+_sourcedirectory="$_projectname-$pkgver"
+
+build() {
+	cd "$srcdir/$_sourcedirectory/"
+	dune build -p "$_projectname" --verbose
+}
+
+check() {
+	cd "$srcdir/$_sourcedirectory/"
+	dune runtest -p "$_projectname" --verbose
+}
+
+package() {
+	cd "$srcdir/$_sourcedirectory/"
+	DESTDIR="$pkgdir" dune install --prefix '/usr' --libdir 'lib/ocaml'
+
+	install -dm755 "$pkgdir/usr/share/doc/$pkgname"
+	mv "$pkgdir/usr/doc/$_projectname/"* "$pkgdir/usr/share/doc/$pkgname/"
+	rm -r "$pkgdir/usr/doc/"
+
+	install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
+	ln -sf "/usr/share/doc/$pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}