[arch-commits] Commit in gnome-shell-extensions/repos (2 files)

[Jan Steffens]

    Date: Monday, November 8, 2021 @ 20:09:24
  Author: heftig
Revision: 427581

archrelease: copy trunk to gnome-unstable-any

Added:
  gnome-shell-extensions/repos/gnome-unstable-any/
  gnome-shell-extensions/repos/gnome-unstable-any/PKGBUILD
    (from rev 427574, gnome-shell-extensions/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: gnome-shell-extensions/repos/gnome-unstable-any/PKGBUILD (from rev 427574, gnome-shell-extensions/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-any/PKGBUILD	                        (rev 0)
+++ gnome-unstable-any/PKGBUILD	2021-11-08 20:09:24 UTC (rev 427581)
@@ -0,0 +1,45 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=gnome-shell-extensions
+pkgver=41.0
+pkgrel=1
+pkgdesc="Extensions for GNOME shell, including classic mode"
+url="https://wiki.gnome.org/Projects/GnomeShell/Extensions"
+arch=(any)
+license=(GPL)
+makedepends=(meson git sassc)
+optdepends=('gnome-menus: applications menu extension')
+groups=(gnome)
+_commit=4ccf12e9889c7947c9a04f3ef5a78834dc42833a  # tags/41.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell-extensions.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/gnome-shell-sass.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git submodule set-url data/gnome-shell-sass "$srcdir/gnome-shell-sass"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build -D extension_set=all -D classic_mode=true
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  depends=(gnome-shell)
+
+  meson install -C build --destdir "$pkgdir"
+}