[arch-commits] Commit in gnome-music/repos (2 files)

[Jan Steffens]

    Date: Monday, November 8, 2021 @ 20:09:25
  Author: heftig
Revision: 427582

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-music/repos/gnome-unstable-x86_64/
  gnome-music/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 427578, gnome-music/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: gnome-music/repos/gnome-unstable-x86_64/PKGBUILD (from rev 427578, gnome-music/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2021-11-08 20:09:25 UTC (rev 427582)
@@ -0,0 +1,57 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-music
+pkgver=41.0
+pkgrel=1
+epoch=1
+pkgdesc="Music player and management application"
+url="https://wiki.gnome.org/Apps/Music"
+arch=(x86_64)
+license=(GPL)
+depends=(grilo grilo-plugins tracker3-miners libdmapsharing libmediaart gtk3
+         gvfs python-gobject python-cairo gst-plugins-base python-requests
+         libdazzle libhandy)
+makedepends=(gobject-introspection git meson yelp-tools appstream-glib)
+optdepends=('gst-plugins-good: Extra media codecs'
+            'gst-plugins-ugly: Extra media codecs'
+            'gst-plugins-bad: Extra media codecs'
+            'gst-libav: Extra media codecs')
+groups=(gnome)
+_commit=87af8a6dcec4dd404e147919f53c036e233db2fc  # tags/41.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-music.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git"
+        "git+https://gitlab.gnome.org/mschraal/gfm.git")
+sha256sums=('SKIP'
+            'SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git submodule set-url subprojects/libgd "$srcdir/libgd"
+  git submodule set-url subprojects/gfm "$srcdir/gfm"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir="$pkgdir"
+
+  python -m compileall -d /usr/lib "$pkgdir/usr/lib"
+  python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
+}