[arch-commits] Commit in intel-graphics-compiler/repos (2 files)
Bruno Pagani
archange at gemini.archlinux.org
Sat Oct 23 08:42:02 UTC 2021
Date: Saturday, October 23, 2021 @ 08:42:02
Author: archange
Revision: 1032947
archrelease: copy trunk to community-staging-x86_64
Added:
intel-graphics-compiler/repos/community-staging-x86_64/
intel-graphics-compiler/repos/community-staging-x86_64/PKGBUILD
(from rev 1032946, intel-graphics-compiler/trunk/PKGBUILD)
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Copied: intel-graphics-compiler/repos/community-staging-x86_64/PKGBUILD (from rev 1032946, intel-graphics-compiler/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2021-10-23 08:42:02 UTC (rev 1032947)
@@ -0,0 +1,52 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgname=intel-graphics-compiler
+epoch=1
+pkgver=1.0.8744
+pkgrel=2
+pkgdesc="Intel Graphics Compiler for OpenCL"
+arch=(x86_64)
+url="https://github.com/intel/intel-graphics-compiler"
+license=(MIT)
+depends=(llvm-libs intel-opencl-clang ncurses zlib)
+makedepends=(git cmake clang lld llvm python libunwind)
+options=(!emptydirs)
+source=(${url}/archive/igc-${pkgver}.tar.gz
+ ${pkgname}-fix-lld-prebuilt.patch::https://github.com/intel/intel-graphics-compiler/pull/210.patch
+ git+https://github.com/intel/vc-intrinsics.git#commit=e5ad7e02aa4aa21a3cd7b3e5d1f3ec9b95f58872)
+sha256sums=('1e8ef2dcebb670e7d66de053c2b0c92b8cf8733dae04503bf26dfd7cc798b5ef'
+ 'b2da1a00ac59ce7e98fd6cfb554f8974b1500bc1b9973387181414ffa4cffea5'
+ 'SKIP')
+
+prepare() {
+ cd ${pkgname}-igc-${pkgver}
+ patch -p1 < ../${pkgname}-fix-lld-prebuilt.patch
+}
+
+build() {
+ # https://github.com/intel/intel-graphics-compiler/issues/209
+ CXXFLAGS+=' -Wno-error=nonnull'
+ cmake -B build -S ${pkgname}-igc-${pkgver} \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib \
+ -DIGC_OPTION__ARCHITECTURE_TARGET='Linux64' \
+ -DIGC_OPTION__CLANG_MODE=Prebuilds \
+ -DIGC_OPTION__LLD_MODE=Prebuilds \
+ -DIGC_OPTION__LLVM_PREFERRED_VERSION='13.0.0' \
+ -DIGC_OPTION__LLVM_MODE=Prebuilds \
+ -DIGC_OPTION__LINK_KHRONOS_SPIRV_TRANSLATOR=ON \
+ -DIGC_OPTION__USE_KHRONOS_SPIRV_TRANSLATOR_IN_VC=ON \
+ -DIGC_OPTION__SPIRV_TRANSLATOR_MODE=Prebuilds \
+ -DVC_INTRINSICS_SRC="${srcdir}/vc-intrinsics" \
+ -DINSTALL_GENX_IR=ON \
+ -Wno-dev
+ make -C build
+}
+
+package() {
+ make -C build DESTDIR="${pkgdir}" install
+ install -D -m644 ${pkgname}-igc-${pkgver}/LICENSE.md -t "${pkgdir}"/usr/share/licenses/${pkgname}
+ mv "${pkgdir}"/usr/lib/igc/NOTICES.txt "${pkgdir}"/usr/share/licenses/${pkgname}
+}
More information about the arch-commits
mailing list