[arch-commits] Commit in qtcreator/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Antonio Rojas]

    Date: Saturday, October 23, 2021 @ 08:43:48
  Author: arojas
Revision: 426467

archrelease: copy trunk to staging-x86_64

Added:
  qtcreator/repos/staging-x86_64/
  qtcreator/repos/staging-x86_64/PKGBUILD
    (from rev 426466, qtcreator/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: qtcreator/repos/staging-x86_64/PKGBUILD (from rev 426466, qtcreator/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-10-23 08:43:48 UTC (rev 426467)
@@ -0,0 +1,57 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Sven-Hendrik Haase <sh at lutzhaase.com>
+# Contributor: Imanol Celaya <ornitorrincos at archlinux-es.org>
+# Contributor: Lukas Jirkovsky <l.jirkovsky at gmail.com>
+# Contributor: Dan Vratil <progdan at progdansoft.com>
+# Contributor: thotypous <matiasΘarchlinux-br·org>
+# Contributor: delor <bartekpiech gmail com>
+
+pkgname=qtcreator
+pkgver=5.0.2
+_clangver=13.0.0
+pkgrel=2
+pkgdesc='Lightweight, cross-platform integrated development environment'
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL3)
+# Note: built against Qt5 because of https://bugreports.qt.io/browse/QTCREATORBUG-26134
+depends=(qt5-tools qt5-quickcontrols2 qt5-svg qt5-quick3d qt5-webengine qt5-serialport syntax-highlighting # qt6-shadertools qt6-5compat
+         clang=$_clangver clazy yaml-cpp)
+makedepends=(cmake llvm python)
+options=(docs)
+optdepends=('qt5-doc: integrated Qt documentation'
+            'qt5-examples: welcome page examples'
+            'qt5-translations: for other languages'
+            'gdb: debugger'
+            'cmake: cmake project support'
+            'qbs: QBS project support'
+            'x11-ssh-askpass: ssh support'
+            'git: git support'
+            'mercurial: mercurial support'
+            'bzr: bazaar support'
+            'valgrind: analyze support'
+            'perf: performer analyzer'
+            'mlocate: locator filter')
+source=(https://download.qt.io/official_releases/qtcreator/${pkgver%.*}/$pkgver/qt-creator-opensource-src-$pkgver.tar.xz)
+sha256sums=('1bf07150226da46237f26f5eaa9f090ce81ed79b9bc75e0dfa6328043e360103')
+
+build() {
+  cmake -B build -S qt-creator-opensource-src-$pkgver \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBEXECDIR=lib \
+    -DWITH_DOCS=ON \
+    -DBUILD_DEVELOPER_DOCS=ON \
+    -DBUILD_QBS=OFF \
+    -DQTC_CLANG_BUILDMODE_MATCH=ON \
+    -DBUILD_HELVIEWERBACKEND_QTWEBENGINE=ON
+  cmake --build build
+  cmake --build build --target docs
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+# Install docs
+  cp -r build/share/doc "$pkgdir"/usr/share
+
+  install -Dm644 qt-creator-opensource-src-$pkgver/LICENSE.GPL3-EXCEPT "$pkgdir"/usr/share/licenses/qtcreator/LICENSE.GPL3-EXCEPT
+}