[arch-commits] Commit in (5 files)
David Runge
dvzrv at gemini.archlinux.org
Sun Oct 24 20:24:41 UTC 2021
Date: Sunday, October 24, 2021 @ 20:24:40
Author: dvzrv
Revision: 426514
community2extra: Moving wireplumber from community to extra
Added:
wireplumber/
wireplumber/repos/
wireplumber/trunk/
wireplumber/trunk/PKGBUILD
wireplumber/trunk/wireplumber.install
---------------------+
PKGBUILD | 59 ++++++++++++++++++++++++++++++++++++++++++++++++++
wireplumber.install | 24 ++++++++++++++++++++
2 files changed, 83 insertions(+)
Added: wireplumber/trunk/PKGBUILD
===================================================================
--- wireplumber/trunk/PKGBUILD (rev 0)
+++ wireplumber/trunk/PKGBUILD 2021-10-24 20:24:40 UTC (rev 426514)
@@ -0,0 +1,59 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+pkgbase=wireplumber
+pkgname=('wireplumber' 'wireplumber-docs')
+pkgver=0.4.4
+pkgrel=3
+pkgdesc="Session / policy manager implementation for PipeWire"
+arch=('x86_64')
+url="https://gitlab.freedesktop.org/pipewire/wireplumber"
+license=('MIT')
+makedepends=('cmake' 'cpptoml' 'doxygen' 'glib2' 'gobject-introspection'
+'hotdoc' 'lua' 'meson' 'pipewire' 'python-breathe' 'python-sphinx_rtd_theme'
+'python-sphinx' 'systemd')
+checkdepends=('pipewire-alsa' 'pipewire-jack' 'pipewire-pulse')
+source=("$pkgname-$pkgver.tar.gz::https://gitlab.freedesktop.org/pipewire/${pkgname}/-/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('f8d764c1728c2e550fc41044a8ebbbeba27157540077648431796d7de5a04281df00d9742b04c6f76b50e446b2a723f2555520cb953d432f90b05148967de4ef')
+b2sums=('cc2768db3a4f6f26a176c9fff759384fedb020c98540ecbe1e02e28a7f16fa3ecc4ec25de50a65021cabb4e5746c41c683b714e0bc5cf5003f2a7d9c9414516c')
+
+build() {
+ cd "$pkgname-$pkgver"
+ arch-meson \
+ -Dsystem-lua=true \
+ -Dsystemd-system-service=true \
+ -Dsystemd-user-service=true \
+ -Delogind=disabled \
+ build
+ ninja -C build
+}
+
+check() {
+ cd "$pkgname-$pkgver"
+ ninja -C build test || echo "Known to fail: https://gitlab.freedesktop.org/pipewire/wireplumber/-/issues/18"
+}
+
+package_wireplumber() {
+ depends=('gcc-libs' 'glibc' 'lua' 'libgio-2.0.so' 'libglib-2.0.so'
+ 'libgmodule-2.0.so' 'libgobject-2.0.so' 'libpipewire-0.3.so')
+ optdepends=('wireplumber-docs: for documentation')
+ provides=('libwireplumber-0.4.so' 'pipewire-session-manager')
+ conflicts=('pipewire-media-session')
+ install="${pkgname}.install"
+
+ cd "$pkgbase-$pkgver"
+ DESTDIR="${pkgdir}" meson install -C build
+ install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+ install -vDm 644 {NEWS,README}.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+ # remove files provided by wireplumber-docs
+ rm -frv "${pkgdir}/usr/share/doc/${pkgname}/html"
+}
+
+package_wireplumber-docs() {
+ pkgdesc+=" (documentation)"
+
+ cd "$pkgbase-$pkgver"
+ DESTDIR="${pkgdir}" meson install -C build
+ install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+ # remove files provided by wireplumber
+ rm -frv "${pkgdir}/usr/"{bin,include,lib,share/{gir*,wireplumber}} "${pkgdir}/etc/"
+}
Added: wireplumber/trunk/wireplumber.install
===================================================================
--- wireplumber/trunk/wireplumber.install (rev 0)
+++ wireplumber/trunk/wireplumber.install 2021-10-24 20:24:40 UTC (rev 426514)
@@ -0,0 +1,24 @@
+post_install() {
+ # Enable service by default, as it is aliased for
+ # pipewire-session-manager.service, which is required by pipewire.service
+ systemctl --global enable wireplumber.service
+}
+
+post_upgrade() {
+ if (( $(vercmp "$2" '0.4.4-2') < 0)); then
+ printf "\tReenable any per-user enabled wireplumber.service\n \
+ \tmanually to establish a new service alias for\n \
+ \tpipewire-session-manager.service added with 0.4.4.\n"
+ # reenable already enabled global pipewire-media-session.service, as an alias is introduced with 0.3.38
+ if systemctl --global is-enabled -q wireplumber.service; then
+ systemctl --global reenable wireplumber.service
+ fi
+ # in case the service has not been enabled before, enable it:
+ # wireplumber and pipewire-media-session conflict from this point on
+ systemctl --global enable wireplumber.service
+ fi
+}
+
+pre_remove() {
+ systemctl --global disable wireplumber.service
+}
More information about the arch-commits
mailing list