[arch-commits] Commit in (5 files)
Bruno Pagani
archange at gemini.archlinux.org
Sat Oct 30 11:20:23 UTC 2021
Date: Saturday, October 30, 2021 @ 11:20:22
Author: archange
Revision: 1034969
Initial addition of nodejs-lts-gallium to [community]
Added:
nodejs-lts-gallium/
nodejs-lts-gallium/repos/
nodejs-lts-gallium/trunk/
nodejs-lts-gallium/trunk/PKGBUILD
nodejs-lts-gallium/trunk/ares_compat.patch
-------------------+
PKGBUILD | 64 ++++++++++++++++++++++++++++++++++++++++++++++++++++
ares_compat.patch | 19 +++++++++++++++
2 files changed, 83 insertions(+)
Added: nodejs-lts-gallium/trunk/PKGBUILD
===================================================================
--- nodejs-lts-gallium/trunk/PKGBUILD (rev 0)
+++ nodejs-lts-gallium/trunk/PKGBUILD 2021-10-30 11:20:22 UTC (rev 1034969)
@@ -0,0 +1,64 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=nodejs-lts-gallium
+pkgver=16.13.0
+pkgrel=1
+pkgdesc="Evented I/O for V8 javascript (LTS release: Fermium)"
+arch=(x86_64)
+url="https://nodejs.org/"
+license=(MIT)
+depends=(openssl zlib icu libuv c-ares brotli libnghttp2) # http-parser
+makedepends=(python procps-ng)
+optdepends=('npm: nodejs package manager')
+provides=("nodejs=$pkgver")
+conflicts=(nodejs)
+source=(${url}/dist/v${pkgver}/node-v${pkgver}.tar.xz
+ ares_compat.patch)
+# https://nodejs.org/download/release/latest-gallium/SHASUMS256.txt.asc
+sha256sums=(32114b3dc3945ed0f95f8bc33b42c68e0ef18c408cb56122572a163d907ecbcc
+ 59098e466c4e438cc77ac438e7ec78ec8e508ea067ba0db1894420dc4e3154e4)
+validpgpkeys=(C4F0DFFF4E8C1A8236409D08E73BC641CC11F4C8 # Myles Borins <mylesborins at google.com>
+ 77984A986EBC2AA786BC0F66B01FBB92821C587A # Gibson Fahnestock <gibfahn at gmail.com>
+ B9AE9905FFD7803F25714661B63B535A4C206CA9 # Evan Lucas <evanlucas at me.com>
+ DD8F2338BAE7501E3DD5AC78C273792F7D83545D # Rod Vagg <rod at vagg.org>
+ B9E2F5981AA6E0CD28160D9FF13993A75599653C # Shelley Vohr <shelley.vohr at gmail.com>
+ 4ED778F539E3634C779C87C6D7062848A1AB005C # Beth Griggs <Bethany.Griggs at uk.ibm.com>
+ C82FA3AE1CBEDC6BE46B9360C43CEC45C17AB93C # Richard Lau <rlau at redhat.com>
+ 74F12602B6F1C4E913FAA37AD3A89613643B6201) # Danielle Adams <adamzdanielle at gmail.com>
+
+prepare() {
+ cd node-v${pkgver}
+ patch -p1 < ../ares_compat.patch
+}
+
+build() {
+ cd node-v${pkgver}
+
+ ./configure \
+ --prefix=/usr \
+ --with-intl=system-icu \
+ --without-npm \
+ --shared-openssl \
+ --shared-zlib \
+ --shared-libuv \
+ --experimental-http-parser \
+ --shared-cares \
+ --shared-brotli \
+ --shared-nghttp2
+ # --shared-v8
+ # --shared-http-parser
+
+ make
+}
+
+check() {
+ cd node-v${pkgver}
+ make test-only
+}
+
+package() {
+ cd node-v${pkgver}
+ make DESTDIR="${pkgdir}" install
+ install -Dm644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}
Added: nodejs-lts-gallium/trunk/ares_compat.patch
===================================================================
--- nodejs-lts-gallium/trunk/ares_compat.patch (rev 0)
+++ nodejs-lts-gallium/trunk/ares_compat.patch 2021-10-30 11:20:22 UTC (rev 1034969)
@@ -0,0 +1,19 @@
+--- a/src/cares_wrap.h
++++ b/src/cares_wrap.h
+@@ -22,7 +22,15 @@
+ # include <netdb.h>
+ #endif // __POSIX__
+
+-# include <ares_nameser.h>
++#if defined(__ANDROID__) || \
++ defined(__MINGW32__) || \
++ defined(__OpenBSD__) || \
++ defined(_MSC_VER)
++
++# include <nameser.h>
++#else
++# include <arpa/nameser.h>
++#endif
+
+ namespace node {
+ namespace cares_wrap {
More information about the arch-commits
mailing list