[arch-commits] Commit in lib32-harfbuzz/repos (2 files)

[Jan Steffens]

    Date: Friday, September 17, 2021 @ 21:34:22
  Author: heftig
Revision: 1016897

archrelease: copy trunk to multilib-testing-x86_64

Added:
  lib32-harfbuzz/repos/multilib-testing-x86_64/
  lib32-harfbuzz/repos/multilib-testing-x86_64/PKGBUILD
    (from rev 1016896, lib32-harfbuzz/trunk/PKGBUILD)

----------+
 PKGBUILD |   72 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)

Copied: lib32-harfbuzz/repos/multilib-testing-x86_64/PKGBUILD (from rev 1016896, lib32-harfbuzz/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-testing-x86_64/PKGBUILD	2021-09-17 21:34:22 UTC (rev 1016897)
@@ -0,0 +1,72 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Florian Pritz <bluewind at xinu.at>
+
+pkgbase=lib32-harfbuzz
+pkgname=(lib32-harfbuzz lib32-harfbuzz-icu)
+pkgver=3.0.0
+pkgrel=1
+pkgdesc="OpenType text shaping engine (32-bit)"
+url="https://www.freedesktop.org/wiki/Software/HarfBuzz"
+arch=(x86_64)
+license=(MIT)
+makedepends=(lib32-glib2 lib32-freetype2 lib32-icu ragel git python meson
+             harfbuzz)
+checkdepends=(python-fonttools python-setuptools)
+_commit=9c387e20d65a7a366ac270d789f6ad266014c9e0  # tags/3.0.0^0
+source=("git+https://github.com/harfbuzz/harfbuzz#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd harfbuzz
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd harfbuzz
+}
+
+build() {
+  export CC="gcc -m32"
+  export CXX="g++ -m32"
+  export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
+
+  arch-meson harfbuzz build \
+    --libdir=/usr/lib32 \
+    -D cairo=disabled \
+    -D chafa=disabled \
+    -D introspection=disabled \
+    -D docs=disabled
+  meson compile -C build
+}
+
+check() {
+  mkdir -p tmp
+  TMPDIR="$PWD/tmp" meson test -C build --print-errorlogs
+  rm -r tmp
+}
+
+package_lib32-harfbuzz() {
+  depends=(lib32-glib2 lib32-freetype2 libglib-2.0.so libfreetype.so
+           libgobject-2.0.so harfbuzz)
+  provides=(libharfbuzz.so libharfbuzz-subset.so libharfbuzz-gobject.so)
+
+  meson install -C build --destdir "$pkgdir"
+  rm -rf "${pkgdir}"/usr/{include,share,bin}
+
+  # Split harfbuzz-icu
+  mkdir -p hb-icu/usr/lib32/pkgconfig
+  mv -t hb-icu/usr/lib32 "$pkgdir"/usr/lib32/libharfbuzz-icu*
+  mv -t hb-icu/usr/lib32/pkgconfig "$pkgdir"/usr/lib32/pkgconfig/harfbuzz-icu.pc
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}
+
+package_lib32-harfbuzz-icu() {
+  pkgdesc="$pkgdesc (ICU integration)"
+  depends=("lib32-harfbuzz=$pkgver-$pkgrel" lib32-icu libharfbuzz.so harfbuzz-icu)
+  provides=(libharfbuzz-icu.so)
+
+  mv hb-icu/* "$pkgdir"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}