[arch-commits] Commit in harfbuzz/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Friday, September 17, 2021 @ 21:34:24
  Author: heftig
Revision: 424316

archrelease: copy trunk to testing-x86_64

Added:
  harfbuzz/repos/testing-x86_64/
  harfbuzz/repos/testing-x86_64/PKGBUILD
    (from rev 424315, harfbuzz/trunk/PKGBUILD)

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Copied: harfbuzz/repos/testing-x86_64/PKGBUILD (from rev 424315, harfbuzz/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-09-17 21:34:24 UTC (rev 424316)
@@ -0,0 +1,66 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=harfbuzz
+pkgname=(harfbuzz harfbuzz-icu)
+pkgver=3.0.0
+pkgrel=1
+pkgdesc="OpenType text shaping engine"
+url="https://www.freedesktop.org/wiki/Software/HarfBuzz"
+arch=(x86_64)
+license=(MIT)
+makedepends=(glib2 freetype2 graphite cairo icu gobject-introspection gtk-doc
+             ragel git python meson chafa)
+checkdepends=(python-fonttools python-setuptools)
+_commit=9c387e20d65a7a366ac270d789f6ad266014c9e0  # tags/3.0.0^0
+source=("git+https://github.com/harfbuzz/harfbuzz#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd harfbuzz
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd harfbuzz
+}
+
+build() {
+  arch-meson harfbuzz build \
+    -D graphite=enabled
+  meson compile -C build
+}
+
+check() {
+  mkdir -p tmp
+  TMPDIR="$PWD/tmp" meson test -C build --print-errorlogs
+  rm -r tmp
+}
+
+package_harfbuzz() {
+  depends=(glib2 freetype2 graphite libglib-2.0.so libfreetype.so
+           libgobject-2.0.so)
+  provides=(libharfbuzz.so libharfbuzz-subset.so libharfbuzz-gobject.so)
+  optdepends=('cairo: hb-view program'
+              'chafa: hb-view program')
+
+  meson install -C build --destdir "$pkgdir"
+
+  # Split harfbuzz-icu
+  mkdir -p hb-icu/usr/{include/harfbuzz,lib/pkgconfig}
+  mv -t hb-icu/usr/lib "$pkgdir"/usr/lib/libharfbuzz-icu*
+  mv -t hb-icu/usr/lib/pkgconfig "$pkgdir"/usr/lib/pkgconfig/harfbuzz-icu.pc
+  mv -t hb-icu/usr/include/harfbuzz "$pkgdir"/usr/include/harfbuzz/hb-icu.h
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}
+
+package_harfbuzz-icu() {
+  pkgdesc="$pkgdesc (ICU integration)"
+  depends=("harfbuzz=$pkgver-$pkgrel" icu libharfbuzz.so)
+  provides=(libharfbuzz-icu.so)
+
+  mv hb-icu/* "$pkgdir"
+
+  install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 harfbuzz/COPYING
+}