[arch-commits] Commit in gnome-software/repos (2 files)

[Jan Steffens]

    Date: Saturday, April 2, 2022 @ 22:58:04
  Author: heftig
Revision: 441346

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-software/repos/gnome-unstable-x86_64/
  gnome-software/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 441344, gnome-software/trunk/PKGBUILD)

----------+
 PKGBUILD |   73 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)

Copied: gnome-software/repos/gnome-unstable-x86_64/PKGBUILD (from rev 441344, gnome-software/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2022-04-02 22:58:04 UTC (rev 441346)
@@ -0,0 +1,73 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Fabian Bornschein <fabiscafe-cat-mailbox-dog-org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Yosef Or Boczko <yoseforb at gnome.org>
+
+pkgbase=gnome-software
+pkgname=(gnome-software gnome-software-packagekit-plugin)
+pkgver=42.0
+pkgrel=1
+pkgdesc="GNOME Software Tools"
+url="https://wiki.gnome.org/Apps/Software/"
+arch=(x86_64)
+license=(GPL)
+makedepends=(appstream gsettings-desktop-schemas libpackagekit-glib flatpak
+             fwupd docbook-xsl git gobject-introspection gtk-doc meson
+             valgrind gnome-online-accounts libxmlb malcontent gtk4 libadwaita
+             libsysprof-capture)
+options=(debug)
+_commit=efa819612ad3f9e2985f6f5a2e06be54234bd4c8  # tags/42.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-software.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+}
+
+build() {
+  # Ensure static library is non-LTO compatible
+  CFLAGS+=" -ffat-lto-objects"
+
+  # Building with soup3 requires flatpak to be built with soup3
+  arch-meson $pkgbase build -D soup2=true
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_gnome-software() {
+  groups=(gnome)
+  depends=(libxmlb gsettings-desktop-schemas libpackagekit-glib gtk4 libadwaita
+           gnome-online-accounts appstream libsysprof-capture)
+  optdepends=('flatpak: Flatpak support plugin'
+              'fwupd: fwupd support plugin'
+              'malcontent: Parental control plugin')
+
+  meson install -C build --destdir "$pkgdir"
+
+  local pkglibdir="$pkgdir/usr/lib/gnome-software"
+  _pick packagekit-plugin "$pkglibdir"/plugins-*/libgs_plugin_packagekit*.so
+}
+
+package_gnome-software-packagekit-plugin() {
+  pkgdesc="PackageKit support plugin for GNOME Software"
+  depends=(archlinux-appstream-data gnome-software packagekit)
+  mv packagekit-plugin/* "$pkgdir"
+}