[arch-commits] Commit in python-weasyprint/repos (2 files)

[George Rawlinson]

    Date: Tuesday, April 12, 2022 @ 01:58:04
  Author: grawlinson
Revision: 1185924

archrelease: copy trunk to community-any

Added:
  python-weasyprint/repos/community-any/
  python-weasyprint/repos/community-any/PKGBUILD
    (from rev 1185923, python-weasyprint/trunk/PKGBUILD)

----------+
 PKGBUILD |   80 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 80 insertions(+)

Copied: python-weasyprint/repos/community-any/PKGBUILD (from rev 1185923, python-weasyprint/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2022-04-12 01:58:04 UTC (rev 1185924)
@@ -0,0 +1,80 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Florijan Hamzic <florijanh at gmail dot com>
+
+pkgname=python-weasyprint
+pkgver=54.3
+pkgrel=1
+pkgdesc='Utility to render HTML and CSS to PDF'
+arch=('any')
+url='https://weasyprint.org/'
+license=('BSD')
+depends=(
+  'pango'
+  'python-brotli'
+  'python-cffi'
+  'python-cssselect2'
+  'python-fonttools'
+  'python-html5lib'
+  'python-pillow'
+  'python-pydyf'
+  'python-pyphen'
+  'python-tinycss2'
+  'python-zopfli'
+)
+makedepends=(
+  'git'
+  'python-build'
+  'python-installer'
+  'python-flit'
+)
+checkdepends=(
+  'python-pytest'
+  'ghostscript'
+  'ttf-dejavu'
+)
+_commit='2adfe066bd56fe1247f7cd537b6c377755a7e47b'
+source=("$pkgname::git+https://github.com/Kozea/WeasyPrint.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  # thou shalt not lint coding style in integration tests
+  sed -i 's/--isort --flake8 --cov --no-cov-on-fail//' pyproject.toml
+}
+
+build(){
+  cd "$pkgname"
+
+  python \
+    -m build \
+    --wheel \
+    --no-isolation
+}
+
+check() {
+  cd "$pkgname"
+
+  # skip failing tests
+  python -m pytest \
+    --deselect tests/draw/test_gradient.py::test_linear_gradients_5 \
+    --deselect tests/draw/test_gradient.py::test_linear_gradients_12
+}
+
+package() {
+  cd "$pkgname"
+
+  python \
+    -m installer \
+    --destdir="$pkgdir" \
+    dist/*.whl
+
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}