[arch-commits] Commit in python-pgpy/repos (community-any community-any/PKGBUILD)

[George Rawlinson]

    Date: Tuesday, April 12, 2022 @ 03:20:11
  Author: grawlinson
Revision: 1185926

archrelease: copy trunk to community-any

Added:
  python-pgpy/repos/community-any/
  python-pgpy/repos/community-any/PKGBUILD
    (from rev 1185925, python-pgpy/trunk/PKGBUILD)

----------+
 PKGBUILD |   63 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)

Copied: python-pgpy/repos/community-any/PKGBUILD (from rev 1185925, python-pgpy/trunk/PKGBUILD)
===================================================================
--- community-any/PKGBUILD	                        (rev 0)
+++ community-any/PKGBUILD	2022-04-12 03:20:11 UTC (rev 1185926)
@@ -0,0 +1,63 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: James Morris <jmorris at securityinnovation.com>
+
+pkgname=python-pgpy
+pkgver=0.5.4
+pkgrel=2
+pkgdesc="Pretty Good Privacy for Python"
+arch=('any')
+license=('BSD')
+url="https://github.com/SecurityInnovation/PGPy"
+depends=(
+  'python'
+  'python-cryptography'
+  'python-six'
+  'python-pyasn1'
+)
+makedepends=(
+  'git'
+  'python-setuptools'
+)
+checkdepends=(
+  'python-pytest'
+  'python-pytest-order'
+)
+_commit='345f4b8d74f4123b97198e10a383f485f80946d8'
+source=("$pkgname::git+$url.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+prepare() {
+  cd "$pkgname"
+
+  # https://github.com/SecurityInnovation/PGPy/pull/378
+  sed -i '/wheel/d' setup.cfg
+
+  # https://github.com/SecurityInnovation/PGPy/pull/373
+  git cherry-pick --no-commit e2f427ea5c0347fb5995ed2a9bc00f780c212c70
+}
+
+build() {
+  cd "$pkgname"
+
+  python setup.py build
+}
+
+check() {
+  cd "$pkgname"
+
+  pytest
+}
+
+package() {
+  cd "$pkgname"
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}