[arch-commits] Commit in (4 files)

[George Rawlinson]

    Date: Tuesday, April 12, 2022 @ 09:57:06
  Author: grawlinson
Revision: 1185944

addpkg: python-mistletoe 0.8.2-2

Added:
  python-mistletoe/
  python-mistletoe/repos/
  python-mistletoe/trunk/
  python-mistletoe/trunk/PKGBUILD

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Added: python-mistletoe/trunk/PKGBUILD
===================================================================
--- python-mistletoe/trunk/PKGBUILD	                        (rev 0)
+++ python-mistletoe/trunk/PKGBUILD	2022-04-12 09:57:06 UTC (rev 1185944)
@@ -0,0 +1,40 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+
+pkgname=python-mistletoe
+pkgver=0.8.2
+pkgrel=2
+pkgdesc='A fast, extensible Markdown parser in pure Python'
+arch=('any')
+url='https://github.com/miyuchina/mistletoe'
+license=('MIT')
+depends=('python')
+makedepends=('git' 'python-setuptools')
+_commit='5916ebd57a52668976831b2d249e96662cb001f4'
+source=("$pkgname::git+$url.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed 's/^v//'
+}
+
+build() {
+  cd "$pkgname"
+
+  python setup.py build
+}
+
+check() {
+  cd "$pkgname"
+
+  python -m unittest discover test
+}
+
+package() {
+  cd "$pkgname"
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}