[arch-commits] Commit in mkosi/trunk (PKGBUILD)
David Runge
dvzrv at gemini.archlinux.org
Tue Apr 26 09:32:05 UTC 2022
Date: Tuesday, April 26, 2022 @ 09:32:05
Author: dvzrv
Revision: 1190947
upgpkg: mkosi 12-1: Upgrade to 12.
Remove unneeded quotes and curly braces.
Switch to PEP517.
Rely on qemu-img by default (all images are initially qcow2 when built).
Rely on arch-install-scripts in depends (mkosi uses the host OS as target OS by default).
Add zstd to optdepends for zstd compression.
Run pytest in check()
Modified:
mkosi/trunk/PKGBUILD
----------+
PKGBUILD | 67 +++++++++++++++++++++++++++++++++++++------------------------
1 file changed, 41 insertions(+), 26 deletions(-)
Modified: PKGBUILD
===================================================================
--- PKGBUILD 2022-04-26 09:15:55 UTC (rev 1190946)
+++ PKGBUILD 2022-04-26 09:32:05 UTC (rev 1190947)
@@ -1,34 +1,49 @@
# Maintainer: Christian Rebischke <chris.rebischke at archlinux.org>
-# Maintainer: Lucas Werkmeister <mail at lucaswerkmeister.de>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Lucas Werkmeister <mail at lucaswerkmeister.de>
# Contributor: Dave Reisner <dreisner at archlinux.org>
pkgname=mkosi
-pkgver=11
+pkgver=12
pkgrel=1
-pkgdesc='Build Legacy-Free OS Images'
-arch=('any')
-url='https://github.com/systemd/mkosi'
-license=('LGPL2.1')
-depends=('python')
-makedepends=('python-setuptools')
-optdepends=('debootstrap: build Debian or Ubuntu images'
- 'debian-archive-keyring: build Debian images'
- 'ubuntu-keyring: build Ubuntu images'
- 'arch-install-scripts: build Arch images'
- 'gnupg: sign images'
- 'xz: compress images with xz'
- 'btrfs-progs: raw_btrfs and subvolume output formats'
- 'dosfstools: build bootable images'
- 'squashfs-tools: raw_squashfs output format'
- 'tar: tar output format'
- 'cryptsetup: add dm-verity partitions'
- 'edk2-ovmf: run bootable images in QEMU'
- 'qemu: run bootable images in QEMU'
- 'sbsigntools: sign EFI binaries for UEFI SecureBoot')
-source=("${pkgname}-${pkgver}.tar.gz::https://github.com/systemd/mkosi/archive/v$pkgver.tar.gz")
-sha512sums=('c07b092e38e663100cfa00ce58c2b61d306292f69429835915310f9736e11ea1431ae2667e8fca02c2a145aa4f21bd199f956d2882913474c4cee394bb15a8f2')
+pkgdesc="Build Legacy-Free OS Images"
+arch=(any)
+url="https://github.com/systemd/mkosi"
+license=(LGPL2.1)
+depends=(arch-install-scripts python qemu-img)
+makedepends=(python-build python-installer python-setuptools python-wheel)
+checkdepends=(python-pytest)
+optdepends=(
+ 'btrfs-progs: raw_btrfs and subvolume output formats'
+ 'debian-archive-keyring: build Debian images'
+ 'debootstrap: build Debian or Ubuntu images'
+ 'cryptsetup: add dm-verity partitions'
+ 'dosfstools: build bootable images'
+ 'gnupg: sign images'
+ 'qemu: run bootable images using QEMU'
+ 'sbsigntools: sign EFI binaries for UEFI SecureBoot'
+ 'squashfs-tools: raw_squashfs output format'
+ 'tar: tar output format'
+ 'ubuntu-keyring: build Ubuntu images'
+ 'xz: compress images with xz'
+ 'zstd: compress images with zstd'
+)
+source=($pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz)
+sha512sums=('ae59789e3b4855400d130714fac0b3b599b3e69631bc6a5267916697d0722c05a6c788cd70d224917261c931fe93fa287d3d23f6f00849cb80ff9794a13dc04e')
+b2sums=('b4b43e3cd64bc75eaa1993504baa02cc7f35c77fc76d24a88ccc06d4ab566477aa9febca58ac1c397cd32057aa2da8545480e89a1c9b4bd4d4fa516d812237b0')
+build() {
+ cd $pkgname-$pkgver
+ python -m build --wheel --no-isolation
+}
+
+check() {
+ cd $pkgname-$pkgver
+ pytest -vv
+}
+
package() {
- cd "mkosi-$pkgver"
- python setup.py install --root="$pkgdir"
+ cd $pkgname-$pkgver
+ python -m installer --destdir="$pkgdir" dist/*.whl
+ install -vDm 644 {NEWS,README}.md -t "$pkgdir/usr/share/doc/$pkgname/"
}
More information about the arch-commits
mailing list