[arch-commits] Commit in mkosi/repos (2 files)

[David Runge]

    Date: Tuesday, April 26, 2022 @ 09:32:12
  Author: dvzrv
Revision: 1190948

archrelease: copy trunk to community-staging-any

Added:
  mkosi/repos/community-staging-any/
  mkosi/repos/community-staging-any/PKGBUILD
    (from rev 1190947, mkosi/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: mkosi/repos/community-staging-any/PKGBUILD (from rev 1190947, mkosi/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2022-04-26 09:32:12 UTC (rev 1190948)
@@ -0,0 +1,49 @@
+# Maintainer: Christian Rebischke <chris.rebischke at archlinux.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Lucas Werkmeister <mail at lucaswerkmeister.de>
+# Contributor: Dave Reisner <dreisner at archlinux.org>
+
+pkgname=mkosi
+pkgver=12
+pkgrel=1
+pkgdesc="Build Legacy-Free OS Images"
+arch=(any)
+url="https://github.com/systemd/mkosi"
+license=(LGPL2.1)
+depends=(arch-install-scripts python qemu-img)
+makedepends=(python-build python-installer python-setuptools python-wheel)
+checkdepends=(python-pytest)
+optdepends=(
+  'btrfs-progs: raw_btrfs and subvolume output formats'
+  'debian-archive-keyring: build Debian images'
+  'debootstrap: build Debian or Ubuntu images'
+  'cryptsetup: add dm-verity partitions'
+  'dosfstools: build bootable images'
+  'gnupg: sign images'
+  'qemu: run bootable images using QEMU'
+  'sbsigntools: sign EFI binaries for UEFI SecureBoot'
+  'squashfs-tools: raw_squashfs output format'
+  'tar: tar output format'
+  'ubuntu-keyring: build Ubuntu images'
+  'xz: compress images with xz'
+  'zstd: compress images with zstd'
+)
+source=($pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz)
+sha512sums=('ae59789e3b4855400d130714fac0b3b599b3e69631bc6a5267916697d0722c05a6c788cd70d224917261c931fe93fa287d3d23f6f00849cb80ff9794a13dc04e')
+b2sums=('b4b43e3cd64bc75eaa1993504baa02cc7f35c77fc76d24a88ccc06d4ab566477aa9febca58ac1c397cd32057aa2da8545480e89a1c9b4bd4d4fa516d812237b0')
+
+build() {
+  cd $pkgname-$pkgver
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd $pkgname-$pkgver
+  pytest -vv
+}
+
+package() {
+  cd $pkgname-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -vDm 644 {NEWS,README}.md -t "$pkgdir/usr/share/doc/$pkgname/"
+}