[arch-commits] Commit in lib32-pango/repos (2 files)
Jan Steffens
heftig at gemini.archlinux.org
Wed Aug 10 17:48:25 UTC 2022
Date: Wednesday, August 10, 2022 @ 17:48:25
Author: heftig
Revision: 1265064
archrelease: copy trunk to multilib-testing-x86_64
Added:
lib32-pango/repos/multilib-testing-x86_64/
lib32-pango/repos/multilib-testing-x86_64/PKGBUILD
(from rev 1265063, lib32-pango/trunk/PKGBUILD)
----------+
PKGBUILD | 52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
Copied: lib32-pango/repos/multilib-testing-x86_64/PKGBUILD (from rev 1265063, lib32-pango/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD (rev 0)
+++ multilib-testing-x86_64/PKGBUILD 2022-08-10 17:48:25 UTC (rev 1265064)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Biru Ionut <ionut at archlinux.ro>
+# Contributor: Pierre Schmitz <pierre at archlinux.de>
+# Contributor: Mikko Seppälä <t-r-a-y at mbnet.fi>
+
+pkgname=lib32-pango
+pkgver=1.50.9
+pkgrel=1
+epoch=1
+pkgdesc="A library for layout and rendering of text (32-bit)"
+url="https://www.pango.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(lib32-libthai lib32-cairo lib32-libxft lib32-harfbuzz lib32-fribidi pango)
+makedepends=(git meson)
+options=(debug)
+_commit=a3517dcc6de9bae1193075b7112aa7db97b39dcc # tags/1.50.9^0
+source=("git+https://gitlab.gnome.org/GNOME/pango.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd pango
+ git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+ cd pango
+}
+
+build() {
+ export CC="gcc -m32"
+ export CXX="g++ -m32"
+ export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
+
+ arch-meson pango build \
+ --libdir=/usr/lib32 \
+ -D introspection=disabled
+ meson compile -C build
+}
+
+# not running checks: validation breaks when deps
+# (especially harfbuzz) don't match upstream CI
+
+package() {
+ provides=(libpango{,cairo,ft2,xft}-1.0.so)
+
+ meson install -C build --destdir "$pkgdir"
+
+ rm -r "$pkgdir"/usr/{bin,include}
+}
+
+# vim:set sw=2 sts=-1 et:
More information about the arch-commits
mailing list