[arch-commits] Commit in pango/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Jan Steffens
heftig at gemini.archlinux.org
Wed Aug 10 17:48:25 UTC 2022
Date: Wednesday, August 10, 2022 @ 17:48:25
Author: heftig
Revision: 452525
archrelease: copy trunk to testing-x86_64
Added:
pango/repos/testing-x86_64/
pango/repos/testing-x86_64/PKGBUILD
(from rev 452524, pango/trunk/PKGBUILD)
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Copied: pango/repos/testing-x86_64/PKGBUILD (from rev 452524, pango/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2022-08-10 17:48:25 UTC (rev 452525)
@@ -0,0 +1,54 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=pango
+pkgname=(pango pango-docs)
+pkgver=1.50.9
+pkgrel=1
+epoch=1
+pkgdesc="A library for layout and rendering of text"
+url="https://www.pango.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(libthai cairo libxft harfbuzz fribidi)
+makedepends=(gobject-introspection help2man git meson gi-docgen)
+options=(debug)
+_commit=a3517dcc6de9bae1193075b7112aa7db97b39dcc # tags/1.50.9^0
+source=("git+https://gitlab.gnome.org/GNOME/pango.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd pango
+ git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
+}
+
+prepare() {
+ cd pango
+}
+
+build() {
+ arch-meson pango build \
+ -D gtk_doc=true
+ meson compile -C build
+}
+
+# not running checks: validation breaks when deps
+# (especially harfbuzz) don't match upstream CI
+
+package_pango() {
+ provides=(libpango{,cairo,ft2,xft}-1.0.so)
+
+ meson install -C build --destdir "$pkgdir"
+
+ mkdir -p doc/usr/share
+ mv {"$pkgdir",doc}/usr/share/doc
+}
+
+package_pango-docs() {
+ pkgdesc+=" (documentation)"
+ depends=()
+
+ mv doc/* "$pkgdir"
+}
+
+# vim:set sw=2 sts=-1 et:
More information about the arch-commits
mailing list