[arch-commits] Commit in git-absorb/repos (2 files)

[Felix Yan]

    Date: Friday, August 19, 2022 @ 09:21:09
  Author: felixonmars
Revision: 1269801

archrelease: copy trunk to community-staging-x86_64

Added:
  git-absorb/repos/community-staging-x86_64/
  git-absorb/repos/community-staging-x86_64/PKGBUILD
    (from rev 1269800, git-absorb/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: git-absorb/repos/community-staging-x86_64/PKGBUILD (from rev 1269800, git-absorb/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-19 09:21:09 UTC (rev 1269801)
@@ -0,0 +1,47 @@
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: AsamK <asamk at gmx.de>
+
+pkgname=git-absorb
+pkgver=0.6.7
+pkgrel=2
+pkgdesc="git commit --fixup, but automatic"
+arch=('x86_64')
+url="https://github.com/tummychow/git-absorb"
+license=('BSD')
+depends=('libgit2')
+makedepends=('cargo')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/tummychow/git-absorb/archive/${pkgver}.tar.gz")
+sha256sums=('f562dbcf68c5f687197e8a594cb58cf102cc17a2e9fcf66dbacb83b49e053bd7')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  LIBGIT2_SYS_USE_PKG_CONFIG=1 cargo fetch --locked
+  mkdir completions/
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  LIBGIT2_SYS_USE_PKG_CONFIG=1 cargo build --release --frozen
+  "target/release/$pkgname" --gen-completions bash > "completions/$pkgname.bash"
+  "target/release/$pkgname" --gen-completions fish > "completions/$pkgname.fish"
+  "target/release/$pkgname" --gen-completions zsh > "completions/_$pkgname"
+}
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  LIBGIT2_SYS_USE_PKG_CONFIG=1 cargo test --frozen
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  install -Dm 755 target/release/"${pkgname}" -t "${pkgdir}/usr/bin/"
+  install -Dm 644 "README.md" "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+  install -Dm 644 "LICENSE.md" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm 644 "Documentation/${pkgname}.1" "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+  install -Dm 644 "completions/$pkgname.bash" "${pkgdir}/usr/share/bash-completion/completions/$pkgname"
+  install -Dm 644 "completions/$pkgname.fish" -t "${pkgdir}/usr/share/fish/vendor_completions.d"
+  install -Dm 644 "completions/_$pkgname" -t "${pkgdir}/usr/share/zsh/site-functions"
+}
+
+# vim: ts=2 sw=2 et: