[arch-commits] Commit in git-cliff/repos (2 files)

Felix Yan felixonmars at gemini.archlinux.org
Fri Aug 19 09:24:43 UTC 2022


    Date: Friday, August 19, 2022 @ 09:24:43
  Author: felixonmars
Revision: 1269803

archrelease: copy trunk to community-staging-x86_64

Added:
  git-cliff/repos/community-staging-x86_64/
  git-cliff/repos/community-staging-x86_64/PKGBUILD
    (from rev 1269802, git-cliff/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: git-cliff/repos/community-staging-x86_64/PKGBUILD (from rev 1269802, git-cliff/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-08-19 09:24:43 UTC (rev 1269803)
@@ -0,0 +1,45 @@
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+
+pkgname=git-cliff
+pkgver=0.9.0
+pkgrel=2
+pkgdesc="A highly customizable changelog generator"
+arch=('x86_64')
+url="https://github.com/orhun/git-cliff"
+license=('GPL3')
+depends=('gcc-libs' 'zlib' 'libgit2' 'libgit2.so')
+makedepends=('cargo')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha512sums=('cf24532f068a3a0efdececf1f066130cbb33fbc343884627a095a67f1dc7d8b4bcc83f99e056cb2edce61ecfe866bc45f9062f24faf38b6b881083b3691e2bd4')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  mkdir completions/
+  mkdir man/
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  cargo build --release --frozen --no-default-features
+  OUT_DIR=completions/ "./target/release/$pkgname-completions"
+  OUT_DIR=man/ "./target/release/$pkgname-mangen"
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  cargo test --frozen -- --skip "git_log"
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
+  install -Dm 644 "completions/$pkgname.bash" "$pkgdir/usr/share/bash-completion/completions/$pkgname"
+  install -Dm 644 "completions/$pkgname.fish" -t "$pkgdir/usr/share/fish/vendor_completions.d"
+  install -Dm 644 "completions/_$pkgname" -t "$pkgdir/usr/share/zsh/site-functions"
+  install -Dm 644 "man/$pkgname.1" -t "$pkgdir/usr/share/man/man1"
+}
+
+# vim: ts=2 sw=2 et:



More information about the arch-commits mailing list