[arch-commits] Commit in (4 files)

[Caleb Maclennan]

    Date: Monday, August 22, 2022 @ 10:37:49
  Author: alerque
Revision: 1274611

Initial add of python-flit-scm, build dependency for python-exceptiongroup, new dependency for python-cattrs

Added:
  python-flit-scm/
  python-flit-scm/repos/
  python-flit-scm/trunk/
  python-flit-scm/trunk/PKGBUILD

----------+
 PKGBUILD |   31 +++++++++++++++++++++++++++++++
 1 file changed, 31 insertions(+)

Added: python-flit-scm/trunk/PKGBUILD
===================================================================
--- python-flit-scm/trunk/PKGBUILD	                        (rev 0)
+++ python-flit-scm/trunk/PKGBUILD	2022-08-22 10:37:49 UTC (rev 1274611)
@@ -0,0 +1,31 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Padraic Fanning <fanninpm AT miamioh DOT edu>
+
+_name=flit_scm
+pkgname=python-${_name//_/-}
+pkgver=1.7.0
+pkgrel=2
+pkgdesc='A PEP 518 backend using setuptools_scm to generate a version file, then flit to build'
+arch=(any)
+url="https://gitlab.com/WillDaSilva/$_name"
+license=(MIT)
+depends=(python
+         python-flit-core
+         python-setuptools-scm
+         python-tomli)
+makedepends=(python-{build,installer,wheel})
+_archive="$_name-$pkgver"
+source=("$_archive.tar.gz::$url/-/archive/$pkgver/$_archive.tar.gz")
+sha256sums=('05a267d77f6f8ca50a053786fe3c1a74f7222f2955292f2e6c03d2d064a141dc')
+
+build() {
+    cd "$_archive"
+    export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+    python -m build -wn
+}
+
+package() {
+    cd "$_archive"
+    export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+    python -m installer -d "$pkgdir" dist/*.whl
+}