[arch-commits] Commit in (4 files)

Caleb Maclennan alerque at gemini.archlinux.org
Mon Aug 22 10:44:51 UTC 2022


    Date: Monday, August 22, 2022 @ 10:44:51
  Author: alerque
Revision: 1274619

Initial add of python-exceptiongroup, new dependency for python-cattrs

Added:
  python-exceptiongroup/
  python-exceptiongroup/repos/
  python-exceptiongroup/trunk/
  python-exceptiongroup/trunk/PKGBUILD

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Added: python-exceptiongroup/trunk/PKGBUILD
===================================================================
--- python-exceptiongroup/trunk/PKGBUILD	                        (rev 0)
+++ python-exceptiongroup/trunk/PKGBUILD	2022-08-22 10:44:51 UTC (rev 1274619)
@@ -0,0 +1,36 @@
+# Maintainer: Caleb Maclennan <caleb at alerque.com>
+# Contributor: Padraic Fanning <fanninpm AT miamioh DOT edu>
+
+pkgname=python-exceptiongroup
+_pyname=${pkgname#python-}
+pkgver=1.0.0rc8
+pkgrel=3
+pkgdesc='Backport of PEP 654 (exception groups)'
+arch=(any)
+url="https://github.com/agronholm/$_pyname"
+license=(MIT)
+depends=(python)
+makedepends=(python-{build,installer,wheel}
+             python-flit-scm)
+checkdepends=(python-pytest)
+_archive="$pkgname-$pkgver"
+source=("$url/archive/$pkgver/$_archive.tar.gz")
+sha256sums=('eea886105f6b88625ce391b2cba78334f6f20edb6c9a2b613eaaffbe9b2dcf96')
+
+build() {
+	cd "$_archive"
+	export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+	python -m build -wn
+}
+
+check() {
+	cd "$_archive"
+	PYTHONPATH=src pytest
+}
+
+package() {
+	cd "$_archive"
+	export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+	python -m installer -d "$pkgdir" dist/*.whl
+	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
+}



More information about the arch-commits mailing list