[arch-commits] Commit in (4 files)

Felix Yan felixonmars at gemini.archlinux.org
Wed Aug 24 10:53:57 UTC 2022


    Date: Wednesday, August 24, 2022 @ 10:53:57
  Author: felixonmars
Revision: 1276095

addpkg: haskell-ipython-kernel 0.10.2.2-1

Added:
  haskell-ipython-kernel/
  haskell-ipython-kernel/repos/
  haskell-ipython-kernel/trunk/
  haskell-ipython-kernel/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Added: haskell-ipython-kernel/trunk/PKGBUILD
===================================================================
--- haskell-ipython-kernel/trunk/PKGBUILD	                        (rev 0)
+++ haskell-ipython-kernel/trunk/PKGBUILD	2022-08-24 10:53:57 UTC (rev 1276095)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=ipython-kernel
+pkgname=haskell-ipython-kernel
+pkgver=0.10.2.2
+pkgrel=1
+pkgdesc="A library for creating kernels for IPython frontends"
+url="http://github.com/gibiansky/IHaskell"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-cryptonite' 'haskell-memory' 'haskell-temporary'
+         'haskell-unordered-containers' 'haskell-uuid' 'haskell-zeromq4-haskell')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('d8b32834252af6029dd21eb8dd58eb7b529aa221175c72ab16ea4d8bdd5277ff')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=haskell-ipython-kernel --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie' \
+    -f-examples
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}



More information about the arch-commits mailing list