[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, August 24, 2022 @ 10:56:43
  Author: felixonmars
Revision: 1276097

addpkg: haskell-ghc-parser 0.2.3.0-1

Added:
  haskell-ghc-parser/
  haskell-ghc-parser/repos/
  haskell-ghc-parser/trunk/
  haskell-ghc-parser/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: haskell-ghc-parser/trunk/PKGBUILD
===================================================================
--- haskell-ghc-parser/trunk/PKGBUILD	                        (rev 0)
+++ haskell-ghc-parser/trunk/PKGBUILD	2022-08-24 10:56:43 UTC (rev 1276097)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=ghc-parser
+pkgname=haskell-ghc-parser
+pkgver=0.2.3.0
+pkgrel=1
+pkgdesc="Haskell source parser from GHC."
+url="https://github.com/gibiansky/IHaskell"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ghc')
+makedepends=('ghc' 'haskell-cpphs' 'happy')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('96be38d7a94e6e6272d7359a25cdca41477dcc5c04980c1bb9137fc18d1da9ea')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir=haskell-ghc-parser --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie' 
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}