[arch-commits] Commit in cargo-generate/repos (2 files)
David Runge
dvzrv at gemini.archlinux.org
Fri Feb 18 18:03:45 UTC 2022
Date: Friday, February 18, 2022 @ 18:03:45
Author: dvzrv
Revision: 1134015
archrelease: copy trunk to community-staging-x86_64
Added:
cargo-generate/repos/community-staging-x86_64/
cargo-generate/repos/community-staging-x86_64/PKGBUILD
(from rev 1134014, cargo-generate/trunk/PKGBUILD)
----------+
PKGBUILD | 41 +++++++++++++++++++++++++++++++++++++++++
1 file changed, 41 insertions(+)
Copied: cargo-generate/repos/community-staging-x86_64/PKGBUILD (from rev 1134014, cargo-generate/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-02-18 18:03:45 UTC (rev 1134015)
@@ -0,0 +1,41 @@
+# Maintainer: Orhun Parmaksız <orhun at archlinux.org>
+# Contributor: Philipp A. <flying-sheep at web.de>
+
+pkgname=cargo-generate
+pkgver=0.13.0
+pkgrel=2
+pkgdesc="Use pre-existing git repositories as templates"
+arch=('x86_64')
+url="https://github.com/cargo-generate/cargo-generate"
+license=('MIT' 'Apache')
+depends=('curl' 'libgit2')
+makedepends=('cargo' 'libssh2')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha256sums=('00435f45156b3dd2f9dcb539fa16dcc9824a4e59a2bf77e57faeedbcb7a70911')
+
+prepare() {
+ cd "$pkgname-$pkgver"
+ cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+ export RUSTUP_TOOLCHAIN=stable
+ export LIBSSH2_SYS_USE_PKG_CONFIG=1
+ cd "$pkgname-$pkgver"
+ cargo build --release --frozen
+}
+
+check() {
+ export RUSTUP_TOOLCHAIN=stable
+ cd "$pkgname-$pkgver"
+ cargo test --frozen --lib
+}
+
+package() {
+ cd "$pkgname-$pkgver"
+ install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
+ install -Dm 644 README.md -t "$pkgdir/usr/share/doc/$pkgname"
+ install -Dm 644 LICENSE-MIT -t "$pkgdir/usr/share/licenses/$pkgname"
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list