[arch-commits] Commit in lib32-expat/repos (2 files)

[David Runge]

    Date: Sunday, January 16, 2022 @ 16:54:08
  Author: dvzrv
Revision: 1106374

archrelease: copy trunk to multilib-staging-x86_64

Added:
  lib32-expat/repos/multilib-staging-x86_64/
  lib32-expat/repos/multilib-staging-x86_64/PKGBUILD
    (from rev 1106373, lib32-expat/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: lib32-expat/repos/multilib-staging-x86_64/PKGBUILD (from rev 1106373, lib32-expat/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD	                        (rev 0)
+++ multilib-staging-x86_64/PKGBUILD	2022-01-16 16:54:08 UTC (rev 1106374)
@@ -0,0 +1,48 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+
+_name=expat
+pkgname=lib32-expat
+pkgver=2.4.3
+pkgrel=1
+pkgdesc='An XML Parser library'
+arch=(x86_64)
+url=https://libexpat.github.io/
+license=(MIT)
+depends=(
+  "expat=${pkgver}"
+  lib32-glibc
+)
+makedepends=(cmake)
+source=("https://github.com/libexpat/libexpat/releases/download/R_${pkgver//./_}/${_name}-${pkgver}.tar.bz2"{,.asc})
+sha512sums=('1a77580c10d8cd1eb2c9224697cb73cdad742c1b6cf716d987379d01bb1f66240c315c298f5295f120cf44445521ccb7cdd39db1e743f164b919245a35a9468e'
+            'SKIP')
+b2sums=('02e74fd8f2b169488da5d2e5a7f13ea242fd9a35ec44b968a755298748299d8bcf6eabcb843470aa7e6b9a7f30d6649834c18c52f89ef0286671499abc7d4f37'
+        'SKIP')
+validpgpkeys=(3176EF7DB2367F1FCA4F306B1F9B0E909AF37285) # Sebastian Pipping
+
+build() {
+  export CC='gcc -m32'
+  export CXX='c++ -m32'
+  export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+  cmake -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=lib32 \
+        -DCMAKE_BUILD_TYPE=None \
+        -W no-dev \
+        -B build \
+        -S "${_name}-$pkgver"
+  make VERBOSE=1 -C build
+}
+
+check() {
+  make VERBOSE=1 -C build test
+}
+
+package() {
+  make VERBOSE=1 DESTDIR="$pkgdir" -C build install
+  install -vDm 644 "${_name}-$pkgver/COPYING" -t "${pkgdir}/usr/share/licenses/$pkgname/"
+  rm -rf "${pkgdir}"/usr/{bin,include,share/man,share/doc}
+}
+
+# vim: ts=2 sw=2 et: