[arch-commits] Commit in lib32-expat/repos (2 files)
David Runge
dvzrv at gemini.archlinux.org
Sun Jan 30 10:38:47 UTC 2022
Date: Sunday, January 30, 2022 @ 10:38:46
Author: dvzrv
Revision: 1120212
archrelease: copy trunk to multilib-staging-x86_64
Added:
lib32-expat/repos/multilib-staging-x86_64/
lib32-expat/repos/multilib-staging-x86_64/PKGBUILD
(from rev 1120211, lib32-expat/trunk/PKGBUILD)
----------+
PKGBUILD | 48 ++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 48 insertions(+)
Copied: lib32-expat/repos/multilib-staging-x86_64/PKGBUILD (from rev 1120211, lib32-expat/trunk/PKGBUILD)
===================================================================
--- multilib-staging-x86_64/PKGBUILD (rev 0)
+++ multilib-staging-x86_64/PKGBUILD 2022-01-30 10:38:46 UTC (rev 1120212)
@@ -0,0 +1,48 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+
+_name=expat
+pkgname=lib32-expat
+pkgver=2.4.4
+pkgrel=1
+pkgdesc='An XML Parser library'
+arch=(x86_64)
+url=https://libexpat.github.io/
+license=(MIT)
+depends=(
+ "expat=${pkgver}"
+ lib32-glibc
+)
+makedepends=(cmake)
+source=("https://github.com/libexpat/libexpat/releases/download/R_${pkgver//./_}/${_name}-${pkgver}.tar.bz2"{,.asc})
+sha512sums=('ef2df46899f3dc8f9733b7450396366c7d3d38b6b286f65b0ffa0f88c60814340c31ba8545a9b627469ca589c3de46f703490e0388160f0310cd891780684867'
+ 'SKIP')
+b2sums=('4743e8477909168241312d3f72f7c5dbc88921e60d96c4111d1bd0f1a94db106b6c764b340275d7d746f316d4e32e6a5aabd27fc599fda7ae6d68e0f0d744999'
+ 'SKIP')
+validpgpkeys=(3176EF7DB2367F1FCA4F306B1F9B0E909AF37285) # Sebastian Pipping
+
+build() {
+ export CC='gcc -m32'
+ export CXX='c++ -m32'
+ export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+ cmake -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib32 \
+ -DCMAKE_BUILD_TYPE=None \
+ -W no-dev \
+ -B build \
+ -S "${_name}-$pkgver"
+ make VERBOSE=1 -C build
+}
+
+check() {
+ make VERBOSE=1 -C build test
+}
+
+package() {
+ make VERBOSE=1 DESTDIR="$pkgdir" -C build install
+ install -vDm 644 "${_name}-$pkgver/COPYING" -t "${pkgdir}/usr/share/licenses/$pkgname/"
+ rm -rf "${pkgdir}"/usr/{bin,include,share/man,share/doc}
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list