[arch-commits] Commit in openmw/repos (2 files)

[Sven-Hendrik Haase]

    Date: Sunday, January 23, 2022 @ 18:22:44
  Author: svenstaro
Revision: 1113800

archrelease: copy trunk to community-staging-x86_64

Added:
  openmw/repos/community-staging-x86_64/
  openmw/repos/community-staging-x86_64/PKGBUILD
    (from rev 1113799, openmw/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: openmw/repos/community-staging-x86_64/PKGBUILD (from rev 1113799, openmw/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2022-01-23 18:22:44 UTC (rev 1113800)
@@ -0,0 +1,37 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at archlinux.org>
+# Contributor: Sandy Carter <bwrsandman at gmail.com>
+
+pkgname=openmw
+pkgver=0.47.0
+pkgrel=3
+pkgdesc="Open-source engine reimplementation for the role-playing game Morrowind"
+arch=('x86_64')
+url="http://www.openmw.org"
+license=('GPL3' 'MIT' 'custom')
+depends=('openal' 'openscenegraph' 'mygui' 'qt5-base' 'ffmpeg' 'sdl2' 'unshield' 'libxt' 'boost-libs')
+makedepends=('cmake' 'boost' 'doxygen' 'ninja')
+source=("https://github.com/OpenMW/openmw/archive/refs/tags/openmw-0.47.0.tar.gz")
+sha512sums=('517e650d0054cdba8d38de05ed3975b0fcf8de32fda59c8df7c34b973e5390efa0dd9ec79babdfdaa79dee7aa8a75009776f62fad91b9aa9aa28016c5032652b')
+
+build() {
+  cd openmw-openmw-$pkgver
+  # We can't use system bullet because openmw needs a version built with double
+  # precision but the one we ship in Arch is built with single precision for
+  # performance reasons.
+  cmake \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DOPENMW_LTO_BUILD=ON \
+    -DDESIRED_QT_VERSION=5 \
+    -DOPENMW_USE_SYSTEM_BULLET=OFF \
+    -GNinja \
+    -Bbuild
+  ninja -C build
+}
+
+package() {
+  cd openmw-openmw-$pkgver
+  DESTDIR="$pkgdir" ninja -C build install
+}
+
+# vim: ts=2 sw=2 et: