[arch-commits] Commit in handbrake/repos (2 files)
Evangelos Foutras
foutrelis at gemini.archlinux.org
Sun Jan 23 18:26:23 UTC 2022
Date: Sunday, January 23, 2022 @ 18:26:23
Author: foutrelis
Revision: 1113808
archrelease: copy trunk to community-staging-x86_64
Added:
handbrake/repos/community-staging-x86_64/
handbrake/repos/community-staging-x86_64/PKGBUILD
(from rev 1113807, handbrake/trunk/PKGBUILD)
----------+
PKGBUILD | 61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 61 insertions(+)
Copied: handbrake/repos/community-staging-x86_64/PKGBUILD (from rev 1113807, handbrake/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2022-01-23 18:26:23 UTC (rev 1113808)
@@ -0,0 +1,61 @@
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: Sebastien Piccand <sebcactus gmail com>
+
+pkgname=('handbrake' 'handbrake-cli')
+pkgver=1.5.1
+pkgrel=2
+arch=('x86_64')
+url="https://handbrake.fr/"
+license=('GPL')
+_commondeps=('libxml2' 'libass' 'libvorbis' 'opus' 'speex' 'libtheora' 'lame'
+ 'x264' 'jansson' 'libvpx' 'libva' 'numactl' 'bzip2' 'gcc-libs'
+ 'zlib' 'xz' 'libjpeg-turbo')
+_guideps=('gst-plugins-base' 'gtk3' 'librsvg' 'libgudev')
+makedepends=('intltool' 'python' 'nasm' 'wget' 'cmake' 'meson'
+ "${_commondeps[@]}" "${_guideps[@]}")
+options=('!lto') # https://bugs.archlinux.org/task/72600
+source=(https://github.com/HandBrake/HandBrake/releases/download/$pkgver/HandBrake-$pkgver-source.tar.bz2{,.sig})
+sha256sums=('3999fe06d5309c819799a73a968a8ec3840e7840c2b64af8f5cdb7fd8c9430f0'
+ 'SKIP')
+validpgpkeys+=('1629C061B3DDE7EB4AE34B81021DB8B44E4A8645') # HandBrake Team <developers at handbrake.fr>
+
+prepare() {
+ cd "$srcdir/HandBrake-$pkgver"
+}
+
+build() {
+ cd "$srcdir/HandBrake-$pkgver"
+
+ ./configure \
+ --prefix=/usr \
+ --enable-qsv
+ make -C build
+}
+
+package_handbrake() {
+ pkgdesc="Multithreaded video transcoder"
+ depends=('desktop-file-utils' 'hicolor-icon-theme'
+ "${_commondeps[@]}" "${_guideps[@]}")
+ optdepends=('gst-plugins-good: for video previews'
+ 'gst-libav: for video previews'
+ 'intel-media-sdk: Intel QuickSync support'
+ 'libdvdcss: for decoding encrypted DVDs')
+
+ cd "$srcdir/HandBrake-$pkgver/build"
+
+ make DESTDIR="$pkgdir" install
+ rm "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+package_handbrake-cli() {
+ pkgdesc="Multithreaded video transcoder (CLI)"
+ depends=("${_commondeps[@]}")
+ optdepends=('intel-media-sdk: Intel QuickSync support'
+ 'libdvdcss: for decoding encrypted DVDs')
+
+ cd "$srcdir/HandBrake-$pkgver/build"
+ install -D HandBrakeCLI "$pkgdir/usr/bin/HandBrakeCLI"
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list