[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Thursday, June 9, 2022 @ 20:13:23
  Author: felixonmars
Revision: 448090

addpkg: python-nspektr 0.3.0-2

Added:
  python-nspektr/
  python-nspektr/repos/
  python-nspektr/trunk/
  python-nspektr/trunk/PKGBUILD

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Added: python-nspektr/trunk/PKGBUILD
===================================================================
--- python-nspektr/trunk/PKGBUILD	                        (rev 0)
+++ python-nspektr/trunk/PKGBUILD	2022-06-09 20:13:23 UTC (rev 448090)
@@ -0,0 +1,36 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Achmad Fathoni<fathoni.id(at)gmail.com>
+
+pkgname=python-nspektr
+pkgver=0.3.0
+pkgrel=2
+pkgdesc="A distribution package dependency inspector"
+arch=('any')
+url="https://github.com/jaraco/nspektr"
+license=('MIT')
+depends=('python-jaraco.context' 'python-jaraco.functools' 'python-more-itertools'
+         'python-packaging')
+makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools-scm')
+checkdepends=('python-pytest-black' 'python-pytest-checkdocs' 'python-pytest-cov'
+              'python-pytest-enabler' 'python-pytest-flake8' 'python-pytest-mypy'
+              'python-pip')
+source=("https://github.com/jaraco/nspektr/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('fdcf6db3d7cc611bff70ae789e0be32a8dfa52e26efc0b8486a1e78a3cc2a74d')
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+
+build() {
+  cd nspektr-$pkgver
+  python -m build -wn
+}
+
+check() {
+  cd nspektr-$pkgver
+  python -m pytest
+}
+
+package() {
+  cd nspektr-$pkgver
+  python -m installer --destdir="$pkgdir" dist/*.whl
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+}