[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Thursday, June 9, 2022 @ 20:17:46
  Author: felixonmars
Revision: 1229751

addpkg: haskell-monad-parallel 0.8-1

Added:
  haskell-monad-parallel/
  haskell-monad-parallel/repos/
  haskell-monad-parallel/trunk/
  haskell-monad-parallel/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: haskell-monad-parallel/trunk/PKGBUILD
===================================================================
--- haskell-monad-parallel/trunk/PKGBUILD	                        (rev 0)
+++ haskell-monad-parallel/trunk/PKGBUILD	2022-06-09 20:17:46 UTC (rev 1229751)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=monad-parallel
+pkgname=haskell-monad-parallel
+pkgver=0.8
+pkgrel=1
+pkgdesc="Parallel execution of monadic computations"
+url="https://hub.darcs.net/blamario/SCC.wiki/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-parallel' 'haskell-transformers-compat')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('44658c1d4036a390a6c6597866e212f73c058ac3b369b8763e0f10c2382b20c9')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie' 
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 BSD3-LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/BSD3-LICENSE.txt
+}